# Copyright 2021 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/sanitizers/sanitizers.gni")
import("//third_party/flatbuffers/flatbuffer.gni")
import("//third_party/tflite/tflite_target.gni")

config("tensorflow-text-config") {
  include_dirs = [
    "src",
    "shims",
    "$root_gen_dir/third_party/tensorflow-text/src",
  ]
}

config("tensorflow-text-flags") {
  cflags = [
    "-Wno-comment",

    # Avoids an error pulling in a TFLite use of tsl::mutex. This is here
    # rather than as a public config in TFLite's BUILD.gn to avoid propagating
    # this disable into more Chrome code than is necessary.
    "-Wno-deprecated-declarations",
  ]
}

static_library("tensorflow-text") {
  sources = [
    "src/tensorflow_text/core/kernels/disjoint_set_forest.h",
    "src/tensorflow_text/core/kernels/mst_solver.h",
    "src/tensorflow_text/core/kernels/regex_split.cc",
    "src/tensorflow_text/core/kernels/regex_split.h",
    "src/tensorflow_text/core/kernels/wordpiece_tokenizer.cc",
    "src/tensorflow_text/core/kernels/wordpiece_tokenizer.h",
  ]

  deps = [
    "//third_party/abseil-cpp:absl",
    "//third_party/icu",
    "//third_party/re2",
  ]

  configs -= [ "//build/config/compiler:chromium_code" ]
  configs += [
    ":tensorflow-text-flags",
    "//build/config/compiler:no_chromium_code",
  ]

  public_configs = [ ":tensorflow-text-config" ]
}

flatbuffer("bert_model_schemas") {
  sources = [
    "src/tensorflow_text/core/kernels/fast_bert_normalizer_model.fbs",
    "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer_model.fbs",
  ]
}

if (!is_fuchsia) {
  tflite_static_library("shimed_bert_model_ops") {
    sources = [
      "src/tensorflow_text/core/kernels/darts_clone_trie_wrapper.h",
      "src/tensorflow_text/core/kernels/fast_bert_normalizer.h",
      "src/tensorflow_text/core/kernels/fast_bert_normalizer_kernel_template.h",
      "src/tensorflow_text/core/kernels/fast_bert_normalizer_tflite.cc",
      "src/tensorflow_text/core/kernels/fast_bert_normalizer_tflite.h",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer.cc",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer.h",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer_kernel_template.h",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer_tflite.cc",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer_tflite.h",
      "src/tensorflow_text/core/kernels/fast_wordpiece_tokenizer_utils.h",
    ]

    deps = [
      ":bert_model_schemas",
      ":tensorflow-text",
      "//third_party/abseil-cpp:absl",
      "//third_party/flatbuffers",
      "//third_party/icu",
      "//third_party/re2",
    ]
    conditional_deps = [ "//third_party/tflite" ]

    configs_to_remove = [ "//build/config/compiler:chromium_code" ]
    configs_to_add = [
      ":tensorflow-text-flags",
      "//build/config/compiler:no_chromium_code",
      "//third_party/ml_dtypes:ml_dtypes-includes",
    ]

    public_configs = [ ":tensorflow-text-config" ]
  }
}