# Copyright 2022 The Chromium OS Authors. All rights reserved.
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//testing/test.gni")
import("//third_party/protobuf/proto_library.gni")
group("all") {
  deps = [
    ":libpuffdiff",
    ":libpuffin-proto",
    ":libpuffpatch",
    ":puffin",
  ]
}

config("target_defaults") {
  cflags = [ "-Wextra" ]
  cflags_cc = [
    "-Wnon-virtual-dtor",
    "-Wno-unused-parameter",
  ]
  include_dirs = [
    "//third_party/puffin/src/include",
    "//third_party",
    "//components",
  ]
  defines = [ "_FILE_OFFSET_BITS=64" ]
}

proto_library("libpuffin-proto") {
  sources = [ "src/puffin.proto" ]
  proto_out_dir = "puffin/src"
}

static_library("libpuffin-common") {
  configs += [ ":target_defaults" ]
  sources = [ "src/file_stream.cc" ]
  deps = [ "//base" ]
}

static_library("libpuffpatch") {
  configs += [ ":target_defaults" ]
  deps = [
    ":libpuffin-common",
    ":libpuffin-proto",
    "//base",
    "//components/zucchini:zucchini_lib",
    "//third_party/brotli:dec",
    "//third_party/brotli:enc",
  ]
  sources = [
    "src/bit_reader.cc",
    "src/bit_writer.cc",
    "src/brotli_util.cc",
    "src/huffer.cc",
    "src/huffman_table.cc",
    "src/memory_stream.cc",
    "src/puff_reader.cc",
    "src/puff_writer.cc",
    "src/puffer.cc",
    "src/puffin_stream.cc",
    "src/puffpatch.cc",
  ]
}

static_library("libpuffdiff") {
  configs += [ ":target_defaults" ]
  deps = [
    ":libpuffin-common",
    ":libpuffin-proto",
    "//base",
    "//components/zucchini:zucchini_lib",
    "//third_party/brotli:dec",
    "//third_party/brotli:enc",
  ]
  sources = [
    "src/puffdiff.cc",
    "src/utils.cc",
  ]
}

executable("puffin") {
  configs += [ ":target_defaults" ]
  deps = [
    ":libpuffdiff",
    ":libpuffpatch",
    "//base",
  ]
  sources = [ "src/chromium_main.cc" ]
}

config("test_defaults") {
  cflags = [
    "-Wextra",
    "-Wno-sign-compare",
  ]
  cflags_cc = [
    "-Wnon-virtual-dtor",
    "-Wno-unused-parameter",
  ]
  include_dirs = [
    "../protobuf/src",
    "src/include",
    "//third_party",
    "//components",
  ]
  defines = [ "_FILE_OFFSET_BITS=64" ]
}

test("puffin_unittests") {
  testonly = true
  configs += [ ":test_defaults" ]
  sources = [
    "src/bit_io_unittest.cc",
    "src/brotli_util_unittest.cc",
    "src/integration_test.cc",
    "src/patching_unittest.cc",
    "src/puff_io_unittest.cc",
    "src/puffin_unittest.cc",
    "src/stream_unittest.cc",
    "src/unittest_common.cc",
    "src/utils_unittest.cc",
  ]
  data = [ "//components/test/data/update_client/puffin_patch_test/" ]
  deps = [
    ":libpuffdiff",
    ":libpuffpatch",
    "//base",
    "//base/test:run_all_unittests",
    "//testing/gtest",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}