# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//third_party/jni_zero/jni_zero.gni")

_enable_generated_benchmark = false

generate_jni("benchmark_jni") {
  sources = [ "java/src/org/jni_zero/benchmark/Benchmark.java" ]
}

android_library("benchmark_java") {
  sources = [ "java/src/org/jni_zero/benchmark/Benchmark.java" ]

  deps = [
    ":benchmark_header_java",
    "//base:base_java",
    "//third_party/jni_zero:jni_zero_java",
  ]
  if (_enable_generated_benchmark) {
    deps += [ "//third_party/jni_zero/benchmarks/generated:generated_java" ]
  }
}

generate_jar_jni("system_jni") {
  classes = [ "java/lang/Integer.class" ]
  visibility = [ ":*" ]
}

source_set("benchmark_native_side") {
  testonly = true
  deps = [
    ":benchmark_jni",
    ":system_jni",
    "//base",
    "//third_party/google_benchmark",
  ]
  sources = [
    "benchmark.cc",
    "benchmark.h",
  ]
  if (_enable_generated_benchmark) {
    deps += [ "//third_party/jni_zero/benchmarks/generated:generated_header" ]
  }
}