# Copyright 2014 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/locales.gni")
import("//tools/grit/grit_rule.gni")

grit_strings("strings") {
  source = "blink_strings.grd"
  inputs = process_file_template(
          xtb_locales,
          [ "translations/blink_strings_{{source_name_part}}.xtb" ])
  outputs = [ "grit/blink_strings.h" ]
  output_prefix = "blink_strings_"
}

# The base strings for the permission element.
grit_strings("permission_element_strings") {
  source = "permission_element_strings.grd"
  inputs = process_file_template(
          xtb_locales,
          [ "translations/permission_element_strings_{{source_name_part}}.xtb" ])
  outputs = [ "grit/permission_element_strings.h" ]
}

action("generate_permission_element_strings_mono_grd") {
  script = "//third_party/blink/renderer/build/scripts/generate_permission_element_grd.py"

  outfile_grd = "$root_gen_dir/third_party/blink/public/strings/permission_element_generated_strings.grd"
  outfile_map = "$root_gen_dir/third_party/blink/renderer/core/html/html_permission_element_strings_map.cc"
  outputs = [
    outfile_grd,
    outfile_map,
  ]

  args = [
    "--output_grd",
    rebase_path(outfile_grd, root_build_dir),
    "--output_map",
    rebase_path(outfile_map, root_build_dir),
    "--input_base_dir",
    rebase_path("//third_party/blink/public/strings/", root_build_dir),
  ]
  deps = [ ":permission_element_strings" ]
}

# The aggregated strings from all locales for the permission element.
grit("permission_element_generated_strings") {
  source = "$root_gen_dir/third_party/blink/public/strings/permission_element_generated_strings.grd"

  # Required because the .grd is generated
  enable_input_discovery_for_gn_analyze = false
  outputs = [
    "grit/permission_element_generated_strings.h",
    "permission_element_generated_strings.pak",
  ]
  deps = [ ":generate_permission_element_strings_mono_grd" ]
}