# Copyright 2015 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/config.gni")
import("//build/config/features.gni")
import("//build/config/ui.gni")
import("//media/media_options.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//testing/libfuzzer/fuzzer_test.gni")
import("//testing/test.gni")

if (is_android) {
  import("//build/config/android/rules.gni")
  import("//third_party/jni_zero/jni_zero.gni")
}

if (is_apple) {
  import("//build/config/apple/mobile_config.gni")  # For `target_platform`
}

# Common configuration for targets in the media/midi directory.
config("midi_config") {
  if (use_alsa && use_udev) {
    defines = [
      "USE_ALSA",
      "USE_UDEV",
    ]
  }

  visibility = [ ":*" ]
}

# Android specific Java source files that are used to generate jni header files.
if (is_android) {
  android_library("midi_java") {
    deps = [
      "//base:base_java",
      "//build/android:build_java",
      "//third_party/androidx:androidx_annotation_annotation_java",
      "//third_party/jni_zero:jni_zero_java",
    ]

    srcjar_deps = [ ":midi_jni_headers" ]
    sources = [
      "java/src/org/chromium/midi/MidiDeviceAndroid.java",
      "java/src/org/chromium/midi/MidiInputPortAndroid.java",
      "java/src/org/chromium/midi/MidiManagerAndroid.java",
      "java/src/org/chromium/midi/MidiOutputPortAndroid.java",
    ]
  }

  generate_jni("midi_jni_headers") {
    sources = [
      "java/src/org/chromium/midi/MidiDeviceAndroid.java",
      "java/src/org/chromium/midi/MidiInputPortAndroid.java",
      "java/src/org/chromium/midi/MidiManagerAndroid.java",
      "java/src/org/chromium/midi/MidiOutputPortAndroid.java",
    ]
  }
}

source_set("midi_export") {
  sources = [ "midi_export.h" ]
}

# Helper target for UMP utilities.
# On Apple platforms, this is linked into the "midi" component.
# On other platforms, it is only linked into tests and fuzzers to avoid
# increasing the production binary size.
source_set("ump_helper") {
  sources = [
    "ump_message_util.cc",
    "ump_message_util.h",
  ]
  configs += [ ":midi_config" ]
  defines = [ "MIDI_IMPLEMENTATION" ]
  public_deps = [
    ":midi_export",
    "//base",
  ]
}

component("midi") {
  sources = [
    "message_util.cc",
    "message_util.h",
    "midi_features.cc",
    "midi_features.h",
    "midi_manager.cc",
    "midi_manager.h",
    "midi_message_queue.cc",
    "midi_message_queue.h",
    "midi_service.cc",
    "midi_service.h",
    "task_service.cc",
    "task_service.h",
  ]

  configs += [ ":midi_config" ]

  defines = [ "MIDI_IMPLEMENTATION" ]
  public_deps = [
    ":midi_export",
    "//base",
  ]
  deps = [ ":mojo" ]
  libs = []

  if (is_android) {
    # TODO(yhirano): Consider having "android" subdirectory.
    sources += [
      "midi_device_android.cc",
      "midi_device_android.h",
      "midi_input_port_android.cc",
      "midi_input_port_android.h",
      "midi_manager_android.cc",
      "midi_manager_android.h",
      "midi_output_port_android.cc",
      "midi_output_port_android.h",
    ]

    deps += [
      ":midi_jni_headers",
      "//base:i18n",
    ]
  }

  if (is_apple) {
    public_deps += [ ":ump_helper" ]
    if (is_ios && target_platform == "tvos") {
      sources += [ "midi_manager_tvos.cc" ]
    } else {
      sources += [
        "midi_manager_mac.cc",
        "midi_manager_mac.h",
      ]
      frameworks = [
        "CoreAudio.framework",
        "CoreFoundation.framework",
        "CoreMIDI.framework",
      ]
    }
  }

  if (is_win) {
    deps += [ "//services/device/public/cpp/usb" ]
    sources += [
      "midi_manager_win.cc",
      "midi_manager_win.h",
      "midi_manager_winrt.cc",
      "midi_manager_winrt.h",
    ]

    libs += [ "setupapi.lib" ]

    # This library is included in base in static builds.
    if (is_component_build) {
      libs += [ "cfgmgr32.lib" ]
    }
  }

  if (use_alsa && use_udev) {
    deps += [ "//crypto" ]
    libs += [ "asound" ]
    sources += [
      "midi_manager_alsa.cc",
      "midi_manager_alsa.h",
    ]
  }

  if (use_udev) {
    deps += [ "//device/udev_linux" ]
  }
}

mojom("mojo") {
  sources = [ "midi_service.mojom" ]

  deps = [ "//mojo/public/mojom/base" ]
}

test("midi_unittests") {
  use_xvfb = use_xvfb_in_this_config

  sources = [
    "message_util_unittest.cc",
    "midi_manager_unittest.cc",
    "midi_message_queue_unittest.cc",
    "task_service_unittest.cc",
    "ump_message_util_unittest.cc",
  ]

  configs += [ ":midi_config" ]
  deps = [
    ":midi",
    ":mojo",
    "//base/test/:run_all_unittests",
    "//base/test/:test_support",
    "//testing/gtest",
  ]
  if (!is_apple) {
    deps += [ ":ump_helper" ]
  }

  if (is_android) {
    deps += [ ":midi_java" ]
  }

  if (is_apple && target_platform != "tvos") {
    sources += [ "midi_manager_mac_unittest.cc" ]
    frameworks = [ "CoreMIDI.framework" ]
  }

  if (is_ios && use_blink) {
    bundle_deps = [
      "//testing/buildbot/filters:midi_unittests_use_blink_filters_bundle_data",
    ]
  }

  if (use_alsa && use_udev) {
    sources += [ "midi_manager_alsa_unittest.cc" ]
  }

  fuzztests = [
    "UmpMessageUtilFuzzTest.DispatchMidiFromUmpWordsDoesNotCrash",
    "UmpMessageUtilFuzzTest.TranslateMidiToUmpWordsDoesNotCrash",
  ]
}

# TODO(crbug.com/327611574): Migrate legacy fuzzer_test targets to FUZZ_TEST.
fuzzer_test("midi_webmidi_data_validator_fuzzer") {
  sources = [ "midi_webmidi_data_validator_fuzzer.cc" ]
  seed_corpus = "fuzz/corpus"
  deps = [ ":midi" ]
}

fuzzer_test("midi_message_queue_fuzzer") {
  sources = [ "midi_message_queue_fuzzer.cc" ]
  seed_corpus = "fuzz/corpus"
  deps = [
    ":midi",
    "//testing/libfuzzer:libfuzzer_base_wrappers",
  ]
}