# Copyright 2016 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//ios/build/chrome_build.gni")

source_set("model") {
  sources = [
    "about_signin_internals_factory.cc",
    "about_signin_internals_factory.h",
    "account_capabilities_fetcher_ios.h",
    "account_capabilities_fetcher_ios.mm",
    "account_consistency_browser_agent.h",
    "account_consistency_browser_agent.mm",
    "account_consistency_service_factory.h",
    "account_consistency_service_factory.mm",
    "account_fetcher_factory_ios.h",
    "account_fetcher_factory_ios.mm",
    "account_investigator_factory.h",
    "account_investigator_factory.mm",
    "account_profile_mapper.h",
    "account_profile_mapper.mm",
    "account_reconcilor_factory.cc",
    "account_reconcilor_factory.h",
    "chrome_account_manager_service.h",
    "chrome_account_manager_service.mm",
    "chrome_account_manager_service_factory.h",
    "chrome_account_manager_service_factory.mm",
    "device_accounts_provider_impl.h",
    "device_accounts_provider_impl.mm",
    "gaia_auth_fetcher_ios.h",
    "gaia_auth_fetcher_ios.mm",
    "gaia_auth_fetcher_ios_bridge.h",
    "gaia_auth_fetcher_ios_bridge.mm",
    "gaia_auth_fetcher_ios_ns_url_session_bridge.h",
    "gaia_auth_fetcher_ios_ns_url_session_bridge.mm",
    "identity_manager_factory.h",
    "identity_manager_factory.mm",
    "ios_chrome_signin_client.h",
    "ios_chrome_signin_client.mm",
    "ios_device_management_error_details.h",
    "ios_device_management_error_details.mm",
    "pattern_account_restriction.h",
    "pattern_account_restriction.mm",
    "signin_client_factory.cc",
    "signin_client_factory.h",
    "signin_error_controller_factory.cc",
    "signin_error_controller_factory.h",
    "signin_metrics_service_factory.h",
    "signin_metrics_service_factory.mm",
    "signin_profile_info_updater.h",
    "signin_profile_info_updater.mm",
    "signin_profile_info_updater_factory.h",
    "signin_profile_info_updater_factory.mm",
    "system_account_updater.h",
    "system_account_updater.mm",
  ]
  deps = [
    ":capabilities_types",
    ":system_identity",
    ":system_identity_manager",
    "//base",
    "//components/browser_sync",
    "//components/content_settings/core/browser",
    "//components/image_fetcher/core",
    "//components/image_fetcher/ios",
    "//components/metrics",
    "//components/policy/core/common",
    "//components/policy/core/common:common_constants",
    "//components/pref_registry",
    "//components/prefs",
    "//components/signin/core/browser",
    "//components/signin/internal/identity_manager",
    "//components/signin/ios/browser",
    "//components/signin/ios/browser:signin_enabled_datasource",
    "//components/signin/public/identity_manager",
    "//components/signin/public/identity_manager/ios",
    "//components/sync",
    "//google_apis",
    "//ios/chrome/app:change_profile_commands",
    "//ios/chrome/app:tests_hook",
    "//ios/chrome/browser/authentication/account_menu/public",
    "//ios/chrome/browser/authentication/ui_bundled:continuation",
    "//ios/chrome/browser/authentication/ui_bundled/signin:signin_headers",
    "//ios/chrome/browser/bookmarks/model:model_utils",
    "//ios/chrome/browser/content_settings/model",
    "//ios/chrome/browser/crash_report/model",
    "//ios/chrome/browser/metrics/model:profile_metrics_service_factory",
    "//ios/chrome/browser/policy/model:policy_util",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/browser",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/model/profile:features",
    "//ios/chrome/browser/shared/model/profile:profile_keyed_service_factory",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/public/commands",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/signin/model/avatar",
    "//ios/chrome/browser/tabs/model:dependency_installer",
    "//ios/chrome/browser/web/model",
    "//ios/chrome/browser/webdata_services/model",
    "//ios/chrome/browser/widget_kit/model:features",
    "//ios/chrome/common",
    "//ios/chrome/common/app_group",
    "//ios/chrome/common/ui/table_view:cells_constants",
    "//ios/chrome/common/ui/util:image_util",
    "//ios/net",
    "//ios/public/provider/chrome/browser/signin:signin_error_api",
    "//ios/public/provider/chrome/browser/signin:signin_identity_api",
    "//ios/public/provider/chrome/browser/signin:signin_resources_api",
    "//ios/web/common",
    "//ios/web/common:web_view_creation_util",
    "//net",
    "//url",
  ]
  if (ios_enable_widget_kit_extension) {
    deps += [ "//ios/chrome/browser/widget_kit/model:model_swift" ]
  }

  public_deps = [
    ":constants",
    ":signin_util",
  ]
}

source_set("authentication_service") {
  sources = [
    "authentication_service.h",
    "authentication_service.mm",
    "authentication_service_delegate.h",
    "authentication_service_observer.h",
    "authentication_service_observer_bridge.h",
    "authentication_service_observer_bridge.mm",
  ]
  deps = [
    ":model",
    ":signin_util",
    ":system_identity",
    ":system_identity_manager",
    ":system_identity_util",
    "//base",
    "//components/browser_sync",
    "//components/policy/core/common",
    "//components/pref_registry",
    "//components/prefs",
    "//components/signin/ios/browser",
    "//components/signin/ios/browser:features",
    "//components/signin/ios/browser:signin_enabled_datasource",
    "//components/signin/public/base",
    "//components/signin/public/base:signin_switches",
    "//components/signin/public/identity_manager",
    "//components/sync/base",
    "//components/sync/service",
    "//google_apis",
    "//ios/chrome/app:tests_hook",
    "//ios/chrome/browser/authentication/ui_bundled/signin:signin_headers",
    "//ios/chrome/browser/bookmarks/model:model_utils",
    "//ios/chrome/browser/crash_report/model",
    "//ios/chrome/browser/policy/model:policy_util",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile:features",
    "//ios/chrome/browser/shared/model/profile:utils",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/widget_kit/model:features",
    "//ios/chrome/common/app_group",
  ]
  if (ios_enable_widget_kit_extension) {
    deps += [ "//ios/chrome/browser/widget_kit/model:model_swift" ]
  }
}

source_set("authentication_service_factory") {
  sources = [
    "authentication_service_delegate_impl.cc",
    "authentication_service_delegate_impl.h",
    "authentication_service_factory.h",
    "authentication_service_factory.mm",
  ]
  deps = [
    ":authentication_service",
    ":model",
    "//base",
    "//components/browsing_data/core",
    "//components/signin/ios/browser:signin_enabled_datasource",
    "//ios/chrome/browser/browsing_data/model",
    "//ios/chrome/browser/ntp/ui_bundled:feature_flags",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/model/profile:features",
    "//ios/chrome/browser/shared/model/profile:profile_keyed_service_factory",
    "//ios/chrome/browser/sync/model",
  ]
}

source_set("account_preview_data_service_factory") {
  sources = [
    "account_preview_data_service_factory.h",
    "account_preview_data_service_factory.mm",
  ]
  deps = [
    ":model",
    "//base",
    "//components/pref_registry",
    "//components/prefs",
    "//components/signin/core/browser",
    "//components/signin/ios/browser",
    "//components/signin/public/base:signin_switches",
    "//ios/chrome/browser/metrics/model:profile_metrics_service_factory",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/model/profile:profile_keyed_service_factory",
    "//ios/chrome/browser/sync/model",
    "//ios/chrome/common",
    "//services/network/public/cpp",
  ]
}

source_set("signin_util") {
  sources = [
    "signin_util.h",
    "signin_util.mm",
  ]
  deps = [
    ":capabilities_types",
    ":constants",
    ":signin_util_internal",
    ":system_identity",
    ":system_identity_manager",
    "//base",
    "//components/prefs",
    "//components/signin/public/identity_manager",
    "//components/subscription_eligibility",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/shared/ui/symbols",
    "//ios/chrome/browser/subscription_eligibility/model",
    "//ios/public/provider/chrome/browser/signin:signin_error_api",
    "//ios/public/provider/chrome/browser/signin:signin_identity_api",
  ]
}

source_set("capabilities_types") {
  sources = [
    "capabilities_dict.h",
    "capabilities_types.h",
  ]
  frameworks = [ "Foundation.framework" ]
}

source_set("constants") {
  sources = [
    "constants.h",
    "constants.mm",
  ]
  deps = [ "//base" ]
}

source_set("signin_util_internal") {
  sources = [
    "signin_util_internal.h",
    "signin_util_internal.mm",
  ]
  visibility = [
    ":signin_util",
    ":signin_util_internal_unit_tests",
    "//ios/chrome/browser/search_engines/model:unit_tests",
  ]
  deps = [
    "//base",
    "//components/signin/public/identity_manager",
    "//ios/chrome/app:tests_hook",
    "//ios/chrome/browser/shared/model/paths",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/common",
  ]
}

source_set("system_identity") {
  sources = [ "system_identity.h" ]
  frameworks = [ "Foundation.framework" ]
}

source_set("system_identity_util") {
  sources = [
    "system_identity_util.h",
    "system_identity_util.mm",
  ]
  deps = [
    ":model",
    ":system_identity",
    "//components/signin/public/base",
    "//components/signin/public/identity_manager",
  ]
}

source_set("system_identity_manager") {
  sources = [
    "refresh_access_token_error.h",
    "system_identity_interaction_manager.h",
    "system_identity_manager.h",
    "system_identity_manager.mm",
    "system_identity_manager_observer.h",
    "system_identity_manager_observer_bridge.h",
    "system_identity_manager_observer_bridge.mm",
  ]
  frameworks = [ "Foundation.framework" ]
  public_deps = [ "//base" ]
  deps = [
    ":capabilities_types",
    ":system_identity",
    "//components/signin/internal/identity_manager",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
  ]
}

source_set("fake_system_identity_manager") {
  testonly = true
  sources = [
    "fake_refresh_access_token_error.h",
    "fake_refresh_access_token_error.mm",
    "fake_system_identity_details.h",
    "fake_system_identity_details.mm",
    "fake_system_identity_interaction_manager.h",
    "fake_system_identity_interaction_manager.mm",
    "fake_system_identity_manager.h",
    "fake_system_identity_manager.mm",
    "fake_system_identity_manager_storage.h",
    "fake_system_identity_manager_storage.mm",
  ]
  public = [
    "fake_refresh_access_token_error.h",
    "fake_system_identity_interaction_manager.h",
    "fake_system_identity_manager.h",
  ]
  public_deps =
      [ "//ios/public/provider/chrome/browser/signin:signin_resources_api" ]
  deps = [
    ":capabilities_types",
    ":fake_account_details_view_controller",
    ":fake_system_identity",
    ":system_identity",
    ":system_identity_manager",
    ":test_account_info",
    ":test_constants",
    "//components/signin/public/identity_manager",
    "//components/signin/public/identity_manager:test_support",
    "//google_apis",
    "//ios/chrome/browser/signin/model:constants",
    "//ios/chrome/common/ui/util",
    "//ios/public/provider/chrome/browser/signin:signin_error_api",
    "//ui/base",
    "//ui/base:test_support",
  ]
  frameworks = [ "Foundation.framework" ]
}

source_set("fake_account_details_view_controller") {
  testonly = true
  visibility = [ ":fake_system_identity_manager" ]
  sources = [
    "fake_account_details_view_controller.h",
    "fake_account_details_view_controller.mm",
  ]
  deps = [
    ":system_identity",
    "//base",
    "//ios/chrome/browser/signin/model:test_constants",
    "//ios/chrome/common/ui/util",
  ]
  frameworks = [ "UIKit.framework" ]
}

source_set("fake_system_identity") {
  testonly = true
  sources = [
    "fake_system_identity.h",
    "fake_system_identity.mm",
  ]
  frameworks = [ "Foundation.framework" ]
  deps = [
    ":system_identity",
    "//base",
    "//google_apis",
  ]
}

source_set("test_account_info") {
  testonly = true
  sources = [
    "test_account_info.h",
    "test_account_info.mm",
    "test_account_info_builder.h",
    "test_account_info_builder.mm",
  ]
  frameworks = [ "Foundation.framework" ]
  deps = [
    "//base",
    "//components/signin/internal/identity_manager:capabilities",
    "//components/signin/public/identity_manager:tribool",
    "//google_apis",
  ]
}

source_set("test_constants") {
  testonly = true
  sources = [
    "test_constants.h",
    "test_constants.mm",
    "test_constants_utils.h",
    "test_constants_utils.mm",
  ]
  frameworks = [ "Foundation.framework" ]
}

source_set("test_support") {
  testonly = true
  sources = [
    "fake_authentication_service_delegate.h",
    "fake_authentication_service_delegate.mm",
    "identity_test_environment_browser_state_adaptor.h",
    "identity_test_environment_browser_state_adaptor.mm",
  ]
  deps = [
    ":authentication_service",
    ":model",
    ":system_identity",
    "//base",
    "//components/image_fetcher/core:test_support",
    "//components/signin/public/base:test_support",
    "//components/signin/public/identity_manager:test_support",
    "//ios/chrome/browser/metrics/model:profile_metrics_service_factory",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/signin/model/trusted_vault",
    "//ios/chrome/browser/sync/model",
  ]
}

source_set("signin_util_internal_unit_tests") {
  testonly = true
  sources = [ "signin_util_internal_unittest.mm" ]
  deps = [
    ":signin_util_internal",
    "//base",
    "//base/test:test_support",
    "//components/signin/public/identity_manager",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "account_capabilities_fetcher_ios_unittest.mm",
    "account_consistency_browser_agent_unittest.mm",
    "account_profile_mapper_unittest.mm",
    "authentication_service_observer_bridge_unittest.mm",
    "authentication_service_unittest.mm",
    "chrome_account_manager_service_unittest.mm",
    "device_accounts_provider_impl_unittest.mm",
    "gaia_auth_fetcher_ios_ns_url_session_bridge_unittest.mm",
    "gaia_auth_fetcher_ios_unittest.mm",
    "pattern_account_restriction_unittest.mm",
    "signin_profile_info_updater_unittest.mm",
    "signin_util_unittest.mm",
    "system_account_updater_unittest.mm",
    "system_identity_manager_unittest.mm",
  ]
  deps = [
    ":authentication_service",
    ":authentication_service_factory",
    ":capabilities_types",
    ":fake_system_identity",
    ":fake_system_identity_manager",
    ":model",
    ":system_identity",
    ":system_identity_manager",
    ":test_support",
    "//base",
    "//base/test:test_support",
    "//components/policy/core/common:common_constants",
    "//components/pref_registry",
    "//components/prefs",
    "//components/prefs:test_support",
    "//components/signin/internal/identity_manager",
    "//components/signin/ios/browser:fake_signin_enabled_datasource",
    "//components/signin/ios/browser:features",
    "//components/signin/public/base:test_support",
    "//components/signin/public/identity_manager",
    "//components/signin/public/identity_manager:test_support",
    "//components/signin/public/identity_manager/ios:test_support",
    "//components/sync:test_support",
    "//components/sync_preferences",
    "//components/sync_preferences:test_support",
    "//components/test/ios",
    "//google_apis",
    "//ios/chrome/app:change_profile_commands",
    "//ios/chrome/app/application_delegate:app_state",
    "//ios/chrome/app/profile",
    "//ios/chrome/browser/content_settings/model",
    "//ios/chrome/browser/lens/model",
    "//ios/chrome/browser/policy/model:policy_util",
    "//ios/chrome/browser/shared/coordinator/scene:scene_state_header",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/browser/test:test_support",
    "//ios/chrome/browser/shared/model/prefs:browser_prefs",
    "//ios/chrome/browser/shared/model/prefs:pref_names",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/model/profile:features",
    "//ios/chrome/browser/shared/model/profile/test",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/public/commands",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/sync/model",
    "//ios/chrome/browser/sync/model:test_support",
    "//ios/chrome/browser/web/model",
    "//ios/chrome/browser/widget_kit/model:features",
    "//ios/chrome/common/app_group",
    "//ios/chrome/test:test_support",
    "//ios/net",
    "//ios/web/common",
    "//ios/web/public/test",
    "//ios/web/public/test/fakes",
    "//net:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//third_party/ocmock",
    "//ui/base:test_support",
  ]
}

source_set("eg2_tests") {
  configs += [ "//build/config/ios:xctest_config" ]
  testonly = true
  sources = [ "authentication_service_egtest.mm" ]
  deps = [
    ":fake_system_identity",
    "//base",
    "//ios/chrome/browser/authentication/test:eg_test_support+eg2",
    "//ios/chrome/test/earl_grey:eg_test_support+eg2",
    "//ios/testing/earl_grey:eg_test_support+eg2",
    "//ui/base",
  ]
  frameworks = [ "UIKit.framework" ]
}