# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("coordinator") {
  sources = [
    "composebox_coordinator.h",
    "composebox_coordinator.mm",
    "composebox_navigation_mediator.h",
    "composebox_navigation_mediator.mm",
  ]
  public_deps = [ ":availability" ]
  deps = [
    ":aim_deps",
    ":clipboard_deps",
    ":common_deps",
    ":input_plate",
    ":lens_deps",
    ":mode_holder",
    ":ntp_deps",
    ":omnibox_deps",
    ":search_deps",
    ":shared_deps",
    ":url_loading_deps",
    "//components/prefs",
    "//ios/chrome/app:tests_hook",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/composebox/debugger",
    "//ios/chrome/browser/composebox/menu/coordinator",
    "//ios/chrome/browser/composebox/model",
    "//ios/chrome/browser/composebox/public",
    "//ios/chrome/browser/composebox/ui",
    "//ios/chrome/browser/composebox/ui/presentation",
    "//ios/chrome/browser/shared/model/browser",
    "//ios/web/public",
    "//ui/base",
  ]
  frameworks = [ "PDFKit.framework" ]
}

source_set("availability") {
  sources = [
    "composebox_availability.h",
    "composebox_availability.mm",
  ]
  public_deps = [ "//ios/chrome/browser/composebox/public:entrypoint" ]
  deps = [
    "//base",
    "//ios/chrome/browser/shared/model/browser",
    "//ios/chrome/browser/shared/public/commands",
    "//ios/chrome/browser/shared/public/features",
  ]
}

source_set("input_plate") {
  sources = [
    "composebox_cobrowse_omnibox_client.h",
    "composebox_cobrowse_omnibox_client.mm",
    "composebox_input_plate_coordinator.h",
    "composebox_input_plate_coordinator.mm",
    "composebox_input_plate_mediator.h",
    "composebox_input_plate_mediator.mm",
    "composebox_omnibox_client.h",
    "composebox_omnibox_client.mm",
    "composebox_omnibox_client_delegate.h",
    "composebox_query_contextualizer_delegate_bridge.h",
    "composebox_query_contextualizer_delegate_bridge.mm",
    "composebox_url_loader.h",
  ]
  public_deps = [
    ":availability",
    ":mode_holder",
  ]
  deps = [
    ":aim_deps",
    ":bookmarks_deps",
    ":common_deps",
    ":input_state_manager",
    ":intelligence_deps",
    ":lens_deps",
    ":location_bar_deps",
    ":ntp_deps",
    ":omnibox_deps",
    ":search_deps",
    ":shared_deps",
    ":url_loading_deps",
    "//components/application_locale_storage",
    "//components/contextual_search:public",
    "//components/contextual_tasks/public:query_contextualizer",
    "//components/favicon/ios",
    "//components/feature_engagement/public",
    "//components/prefs",
    "//components/security_state/ios",
    "//components/strings",
    "//ios/chrome/app:tests_hook",
    "//ios/chrome/app/strings",
    "//ios/chrome/browser/autocomplete/model",
    "//ios/chrome/browser/cobrowse/model",
    "//ios/chrome/browser/cobrowse/model:factory",
    "//ios/chrome/browser/composebox/debugger",
    "//ios/chrome/browser/composebox/menu/coordinator",
    "//ios/chrome/browser/composebox/menu/coordinator:shared_tab",
    "//ios/chrome/browser/composebox/model",
    "//ios/chrome/browser/composebox/public",
    "//ios/chrome/browser/composebox/shared/coordinator",
    "//ios/chrome/browser/composebox/shared/metrics",
    "//ios/chrome/browser/composebox/ui",
    "//ios/chrome/browser/composebox/ui:state",
    "//ios/chrome/browser/composebox/ui/presentation",
    "//ios/chrome/browser/default_browser/model:default_browser_interest_signals",
    "//ios/chrome/browser/drag_and_drop/model",
    "//ios/chrome/browser/favicon/model",
    "//ios/chrome/browser/feature_engagement/model",
    "//ios/chrome/browser/https_upgrades/model",
    "//ios/chrome/browser/intents/model:model_donation_helper",
    "//ios/chrome/browser/prerender/model",
    "//ios/chrome/browser/shared/model/browser",
    "//ios/chrome/browser/shared/model/utils:web_state_deferred_executor",
    "//ios/chrome/browser/signin/model",
    "//ios/chrome/browser/snapshots/model",
    "//ios/chrome/browser/tab_picker/public",
    "//ios/chrome/browser/tab_switcher/ui_bundled:utils",
    "//ios/chrome/browser/tabs/model",
    "//ios/chrome/browser/variations/model/client",
    "//ios/chrome/browser/web/model",
    "//ios/chrome/browser/web/model:page_placeholder",
    "//ios/web",
    "//ios/web/public",
    "//ui/base",
  ]
  frameworks = [ "PDFKit.framework" ]
}

group("aim_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/aim/debugger/coordinator",
    "//ios/chrome/browser/aim/model:aim_availability",
  ]
}

group("url_loading_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/url_loading/model",
    "//ios/chrome/browser/url_loading/model:url_loading_params_header",
  ]
}

group("search_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//components/search",
    "//components/search_engines",
    "//ios/chrome/browser/search_engines/model",
    "//ios/chrome/browser/search_engines/model:template_url_service_factory",
    "//ios/public/provider/chrome/browser/voice_search:voice_search_api",
  ]
}

group("clipboard_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//components/open_from_clipboard",
    "//components/open_from_clipboard:open_from_clipboard_impl",
  ]
}

group("lens_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//components/lens",
    "//ios/chrome/browser/lens/ui_bundled:lens_availability",
    "//ios/chrome/browser/lens/ui_bundled:lens_entrypoint",
  ]
}

group("shared_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/shared/coordinator/chrome_coordinator",
    "//ios/chrome/browser/shared/coordinator/layout_guide",
    "//ios/chrome/browser/shared/model/application_context",
    "//ios/chrome/browser/shared/model/profile",
    "//ios/chrome/browser/shared/model/url",
    "//ios/chrome/browser/shared/model/url:constants",
    "//ios/chrome/browser/shared/model/utils",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/public/commands",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/shared/ui/util",
    "//ios/chrome/browser/shared/ui/util:util_swift",
  ]
}

group("common_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/common",
    "//ios/chrome/common:string_conversions",
    "//ios/chrome/common/ui/favicon",
    "//ios/chrome/common/ui/util",
    "//ios/chrome/common/ui/util:image_util",
  ]
}

group("intelligence_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/intelligence/persist_tab_context/model",
    "//ios/chrome/browser/intelligence/proto_wrappers",
  ]
}

group("ntp_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/ntp/model",
    "//ios/chrome/browser/ntp/model:util",
    "//ios/chrome/browser/ntp/shared/metrics:constants",
    "//ios/chrome/browser/ntp/shared/metrics:home_metrics",
  ]
}

group("location_bar_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/location_bar/model",
    "//ios/chrome/browser/location_bar/ui_bundled:location_bar_model_delegate",
    "//ios/chrome/browser/location_bar/ui_bundled:protocols",
  ]
}

group("omnibox_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//components/contextual_search/internal/ios",
    "//components/omnibox/browser",
    "//components/omnibox/browser:location_bar",
    "//components/omnibox/common",
    "//ios/chrome/browser/omnibox/coordinator",
    "//ios/chrome/browser/omnibox/coordinator/popup",
    "//ios/chrome/browser/omnibox/model",
    "//ios/chrome/browser/omnibox/model/omnibox_focus",
    "//ios/chrome/browser/omnibox/public",
    "//ios/chrome/browser/omnibox/public:features",
    "//ios/chrome/browser/omnibox/ui",
    "//ios/chrome/browser/omnibox/ui:omnibox_internal",
  ]
}

group("bookmarks_deps") {
  visibility = [ ":*" ]
  public_deps = [
    "//ios/chrome/browser/bookmarks/model",
    "//ios/chrome/browser/bookmarks/model:model_utils",
  ]
}

source_set("mode_holder") {
  visibility = [
    ":*",
    "//ios/chrome/browser/composebox/menu/coordinator:*",
    "//ios/chrome/browser/ntp/ui_bundled:*",
  ]
  sources = [
    "composebox_mode_holder.h",
    "composebox_mode_holder.mm",
  ]
  public_deps = [ ":constants" ]
  deps = [
    "//base",
    "//ios/chrome/browser/shared/public/commands",
    "//ios/chrome/browser/shared/public/features",
  ]
}

source_set("constants") {
  sources = [
    "composebox_constants.h",
    "composebox_constants.mm",
  ]
  deps = [
    "//base",
    "//ios/chrome/browser/composebox/public:composebox_mode",
  ]
}

source_set("input_state_manager") {
  sources = [
    "composebox_input_state_manager.h",
    "composebox_input_state_manager.mm",
  ]
  deps = [
    "//base",
    "//components/contextual_search:prefs",
    "//components/contextual_search:public",
    "//components/contextual_search/footprints/internal",
    "//components/contextual_search/footprints/public",
    "//components/omnibox/browser",
    "//components/omnibox/common",
    "//components/prefs",
    "//components/search",
    "//components/search_engines",
    "//components/signin/public/identity_manager",
    "//components/signin/public/identity_manager/objc",
    "//components/strings",
    "//ios/chrome/browser/composebox/coordinator:constants",
    "//ios/chrome/browser/composebox/coordinator:mode_holder",
    "//ios/chrome/browser/composebox/menu/coordinator:shared_tab",
    "//ios/chrome/browser/composebox/public:attachment_options",
    "//ios/chrome/browser/composebox/public:composebox_mode",
    "//ios/chrome/browser/composebox/public:entrypoint",
    "//ios/chrome/browser/composebox/public:features",
    "//ios/chrome/browser/composebox/public:model_options",
    "//ios/chrome/browser/composebox/shared/metrics",
    "//ios/chrome/browser/composebox/ui",
    "//ios/chrome/browser/composebox/ui:state",
    "//ios/chrome/browser/composebox/ui:ui_util",
    "//ios/chrome/browser/search_engines/model",
    "//ios/chrome/browser/shared/model/url",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/shared/public/features:system_flags",
    "//ios/chrome/browser/shared/ui/symbols",
    "//ios/chrome/common:string_conversions",
    "//ios/web/public",
    "//services/network/public/cpp",
    "//third_party/omnibox_proto",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "composebox_cobrowse_omnibox_client_unittest.mm",
    "composebox_input_plate_mediator_unittest.mm",
    "composebox_input_state_manager_unittest.mm",
  ]
  deps = [
    ":coordinator",
    ":input_plate",
    ":input_state_manager",
    ":lens_deps",
    ":mode_holder",
    ":ntp_deps",
    ":url_loading_deps",
    "//base",
    "//base/test:test_support",
    "//components/contextual_search:prefs",
    "//components/contextual_search:public",
    "//components/contextual_search:test_support",
    "//components/contextual_search/footprints/public",
    "//components/contextual_search/internal:test_support",
    "//components/contextual_search/internal/ios",
    "//components/contextual_tasks/public:query_contextualizer",
    "//components/feature_engagement/test:test_support",
    "//components/omnibox/browser",
    "//components/omnibox/browser:test_support",
    "//components/search_engines",
    "//components/search_engines:test_support",
    "//components/signin/public/identity_manager",
    "//components/variations",
    "//components/variations:test_support",
    "//components/version_info:channel",
    "//ios/chrome/browser/cobrowse/model:factory",
    "//ios/chrome/browser/composebox/menu/coordinator:shared_tab",
    "//ios/chrome/browser/composebox/public",
    "//ios/chrome/browser/composebox/shared/metrics:unit_tests",
    "//ios/chrome/browser/composebox/ui",
    "//ios/chrome/browser/composebox/ui:state",
    "//ios/chrome/browser/shared/model/browser/test:test_support",
    "//ios/chrome/browser/shared/model/profile/test",
    "//ios/chrome/browser/shared/model/web_state_list",
    "//ios/chrome/browser/shared/model/web_state_list/test:test_support",
    "//ios/chrome/browser/shared/public/features",
    "//ios/chrome/browser/signin/model",
    "//ios/web/public/test/fakes",
    "//services/network:test_support",
    "//services/network/public/cpp",
    "//testing/gmock",
    "//testing/gtest",
  ]
}