import("//build/config/android/rules.gni")
import("//third_party/jni_zero/jni_zero.gni")

android_library("java") {
  deps = [
    "$google_play_services_package:google_play_services_auth_base_java",
    "$google_play_services_package:google_play_services_base_java",
    "//base:base_java",
    "//base:service_loader_java",
    "//build/android:build_java",
    "//components/cached_flags:java",
    "//components/externalauth/android:java",
    "//extensions/buildflags:buildflags_java",
    "//google_apis/gaia/android:java",
    "//net/android:net_java",
    "//third_party/android_deps:chromium_play_services_availability_java",
    "//third_party/android_deps:com_google_errorprone_error_prone_annotations_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/jni_zero:jni_zero_java",
  ]

  srcjar_deps = [
    ":account_capabilities_constants_javagen",
    ":java_constants",
    ":java_enums",
    ":jni_headers",
    ":signin_java_features_srcjar",
    "//components/signin/public/base:signin_metrics_enum_javagen",
    "//components/signin/public/identity_manager:primary_account_mutator_enum_javagen",
  ]

  sources = [
    "java/src/org/chromium/components/signin/AccessTokenData.java",
    "java/src/org/chromium/components/signin/AccountCapabilitiesFetcher.java",
    "java/src/org/chromium/components/signin/AccountEmailDisplayHook.java",
    "java/src/org/chromium/components/signin/AccountEmailDomainDisplayabilityDelegate.java",
    "java/src/org/chromium/components/signin/AccountManagerDelegate.java",
    "java/src/org/chromium/components/signin/AccountManagerDelegateException.java",
    "java/src/org/chromium/components/signin/AccountManagerFacade.java",
    "java/src/org/chromium/components/signin/AccountManagerFacadeImpl.java",
    "java/src/org/chromium/components/signin/AccountManagerFacadeProvider.java",
    "java/src/org/chromium/components/signin/AccountReauthenticationUtils.java",
    "java/src/org/chromium/components/signin/AccountRestrictionPatternReceiver.java",
    "java/src/org/chromium/components/signin/AccountUtils.java",
    "java/src/org/chromium/components/signin/AccountsChangeObserver.java",
    "java/src/org/chromium/components/signin/AuthException.java",
    "java/src/org/chromium/components/signin/ConnectionRetry.java",
    "java/src/org/chromium/components/signin/NullAccountManagerDelegate.java",
    "java/src/org/chromium/components/signin/PatternMatcher.java",
    "java/src/org/chromium/components/signin/PlatformAccount.java",
    "java/src/org/chromium/components/signin/SigninFeatureMap.java",
    "java/src/org/chromium/components/signin/base/AccountCapabilities.java",
    "java/src/org/chromium/components/signin/base/AccountInfo.java",
    "java/src/org/chromium/components/signin/base/CoreAccountInfo.java",
    "java/src/org/chromium/components/signin/base/SigninDeepLinkPayload.java",
    "java/src/org/chromium/components/signin/identitymanager/AccountManagedStatusFinder.java",
    "java/src/org/chromium/components/signin/identitymanager/IdentityManager.java",
    "java/src/org/chromium/components/signin/identitymanager/IdentityManagerImpl.java",
    "java/src/org/chromium/components/signin/identitymanager/IdentityMutator.java",
    "java/src/org/chromium/components/signin/identitymanager/PrimaryAccountChangeEvent.java",
    "java/src/org/chromium/components/signin/identitymanager/ProfileOAuth2TokenServiceDelegate.java",
  ]
}

# Expose Signin feature flags to Java code
java_cpp_features("signin_java_features_srcjar") {
  visibility = [ ":*" ]
  sources = [ "//components/signin/public/base/signin_switches.cc" ]
  class_name = "org.chromium.components.signin.SigninFeatures"
}

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/components/signin/AccountCapabilitiesFetcher.java",
    "java/src/org/chromium/components/signin/SigninFeatureMap.java",
    "java/src/org/chromium/components/signin/base/AccountCapabilities.java",
    "java/src/org/chromium/components/signin/base/AccountInfo.java",
    "java/src/org/chromium/components/signin/base/CoreAccountInfo.java",
    "java/src/org/chromium/components/signin/base/SigninDeepLinkPayload.java",
    "java/src/org/chromium/components/signin/identitymanager/AccountManagedStatusFinder.java",
    "java/src/org/chromium/components/signin/identitymanager/IdentityManagerImpl.java",
    "java/src/org/chromium/components/signin/identitymanager/IdentityMutator.java",
    "java/src/org/chromium/components/signin/identitymanager/PrimaryAccountChangeEvent.java",
    "java/src/org/chromium/components/signin/identitymanager/ProfileOAuth2TokenServiceDelegate.java",
  ]
}

java_cpp_template("account_capabilities_constants_javagen") {
  sources = [ "java_templates/AccountCapabilitiesConstants.template" ]
  inputs = [
    "//components/signin/internal/identity_manager/account_capabilities_list.h",
  ]
}

java_cpp_strings("java_constants") {
  sources = [ "//components/signin/public/identity_manager/signin_constants.h" ]
  class_name = "org.chromium.components.signin.SigninConstants"
}

java_cpp_enum("java_enums") {
  sources = [
    "//components/signin/public/identity_manager/account_managed_status_finder_outcome.h",
    "//components/signin/public/identity_manager/tribool.h",
  ]
}

generate_jni("test_support_jni_headers") {
  sources = [
    "java/src/org/chromium/components/signin/test/util/AccountCapabilitiesFetcherTestUtil.java",
    "java/src/org/chromium/components/signin/test/util/AccountInfoSerializer.java",
    "java/src/org/chromium/components/signin/test/util/AccountManagerFacadeUtil.java",
  ]
}

android_library("signin_java_test_support") {
  testonly = true
  srcjar_deps = [ ":test_support_jni_headers" ]
  deps = [
    ":java",
    ":signin_test_resources",
    "//base:base_java",
    "//base:base_java_test_support",
    "//components/cached_flags:java",
    "//content/public/test/android:content_java_test_support",
    "//google_apis/gaia/android:java",
    "//third_party/android_deps:guava_android_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_appcompat_appcompat_resources_java",
    "//third_party/hamcrest:hamcrest_core_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/mockito:mockito_java",
  ]
  sources = [
    "java/src/org/chromium/components/signin/test/util/AccountCapabilitiesBuilder.java",
    "java/src/org/chromium/components/signin/test/util/AccountCapabilitiesFetcherTestUtil.java",
    "java/src/org/chromium/components/signin/test/util/AccountHolder.java",
    "java/src/org/chromium/components/signin/test/util/AccountInfoSerializer.java",
    "java/src/org/chromium/components/signin/test/util/AccountManagerFacadeUtil.java",
    "java/src/org/chromium/components/signin/test/util/FakeAccountManagerDelegate.java",
    "java/src/org/chromium/components/signin/test/util/FakeAccountManagerFacade.java",
    "java/src/org/chromium/components/signin/test/util/FakeIdentityManager.java",
    "java/src/org/chromium/components/signin/test/util/FakePlatformAccount.java",
    "java/src/org/chromium/components/signin/test/util/SharedPrefsAccountStorage.java",
    "java/src/org/chromium/components/signin/test/util/SigninMatchers.java",
    "java/src/org/chromium/components/signin/test/util/TestAccounts.java",
  ]
  resources_package = "org.chromium.components.signin.test.util"
}

android_resources("java_resources") {
  sources = [
    "java/res/drawable/account_circle.xml",
    "java/res/drawable/account_circle_with_bg.xml",
    "java/res/drawable/logo_avatar_anonymous.xml",
  ]
}

android_resources("signin_test_resources") {
  testonly = true
  sources = [
    "javatests/res/drawable/test_profile_picture.xml",
    "javatests/res/layout/test_add_account_layout.xml",
  ]
}

android_library("unit_device_javatests") {
  testonly = true
  deps = [
    ":java",
    ":signin_java_test_support",
    "//base:base_java",
    "//base:base_java_test_support",
    "//chrome/test/android:chrome_java_test_support_common",
    "//components/cached_flags:java",
    "//content/public/test/android:content_java_test_support",
    "//extensions/buildflags:buildflags_java",
    "//google_apis/gaia/android:java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_test_monitor_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/google-truth:google_truth_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
  ]

  sources = [ "javatests/src/org/chromium/components/signin/AccountManagerFacadeTest.java" ]
}

robolectric_library("junit") {
  sources = [
    "junit/src/org/chromium/components/signin/AccountManagerFacadeImplTest.java",
    "junit/src/org/chromium/components/signin/AccountReauthenticationUtilsTest.java",
    "junit/src/org/chromium/components/signin/AccountUtilsTest.java",
    "junit/src/org/chromium/components/signin/PatternMatcherTest.java",
    "junit/src/org/chromium/components/signin/base/AccountCapabilitiesTest.java",
  ]
  deps = [
    ":java",
    ":signin_java_test_support",
    "$google_play_services_package:google_play_services_auth_base_java",
    "//base:base_java",
    "//base:base_java_test_support",
    "//base:base_java_test_support_uncommon",
    "//base:base_junit_test_support",
    "//components/cached_flags:java",
    "//components/externalauth/android:java",
    "//extensions/buildflags:buildflags_java",
    "//google_apis/gaia/android:java",
    "//testing/android/junit:junit_test_support",
    "//third_party/android_deps:guava_android_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_test_rules_java",
    "//third_party/google-truth:google_truth_java",
    "//third_party/hamcrest:hamcrest_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
  ]
}