# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/rust.gni")

source_set("private_verification_tokens_public_key") {
  sources = [
    "private_verification_tokens_public_key.cc",
    "private_verification_tokens_public_key.h",
  ]
  deps = [ "//crypto" ]
  public_deps = [
    "//base",
    "//url",
  ]
}

source_set("private_verification_tokens_public_key_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_public_key_unittest.cc" ]
  deps = [
    ":private_verification_tokens_public_key",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

source_set("private_verification_tokens_token") {
  sources = [
    "private_verification_tokens_token.cc",
    "private_verification_tokens_token.h",
  ]
  public_deps = [
    "//base",
    "//url",
  ]
}

source_set("private_verification_tokens_token_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_token_unittest.cc" ]
  deps = [
    ":private_verification_tokens_token",
    "//base",
    "//testing/gtest",
    "//url",
  ]
}

source_set("private_verification_tokens_fetcher") {
  sources = [
    "private_verification_tokens_fetcher.cc",
    "private_verification_tokens_fetcher.h",
  ]
  deps = [
    "//net",
    "//services/network/public/mojom",
  ]
  public_deps = [
    "//base",
    "//services/network/public/cpp",
    "//url",
  ]
}

source_set("private_verification_tokens_fetcher_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_fetcher_unittest.cc" ]
  deps = [
    ":private_verification_tokens_fetcher",
    "//base",
    "//base/test:test_support",
    "//services/network:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

source_set("private_verification_tokens_database") {
  sources = [
    "private_verification_tokens_database.cc",
    "private_verification_tokens_database.h",
  ]
  public_deps = [ ":private_verification_tokens_token" ]
  deps = [
    "//base",
    "//sql",
  ]
}

source_set("private_verification_tokens_database_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_database_unittest.cc" ]
  deps = [
    ":private_verification_tokens_database",
    "//base",
    "//base/test:test_support",
    "//sql",
    "//sql:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

source_set("private_verification_tokens_store") {
  sources = [
    "private_verification_tokens_store.cc",
    "private_verification_tokens_store.h",
  ]
  public_deps = [
    ":private_verification_tokens_database",
    ":private_verification_tokens_token",
  ]
  deps = [ "//base" ]
}

source_set("private_verification_tokens_store_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_store_unittest.cc" ]
  deps = [
    ":private_verification_tokens_store",
    ":private_verification_tokens_token",
    "//base",
    "//base/test:test_support",
    "//sql",
    "//sql:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

source_set("private_verification_tokens_parameters") {
  sources = [
    "private_verification_tokens_parameters.cc",
    "private_verification_tokens_parameters.h",
  ]
}

source_set("private_verification_tokens_parameters_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_parameters_unittest.cc" ]
  deps = [
    ":private_verification_tokens_parameters",
    "//testing/gtest",
  ]
}

source_set("private_verification_tokens_issuer_config") {
  sources = [
    "private_verification_tokens_issuer_config.cc",
    "private_verification_tokens_issuer_config.h",
    "private_verification_tokens_issuer_config_internal.h",
  ]
  public_deps = [
    "//base",
    "//url",
  ]
  deps = [
    ":private_verification_tokens_parameters",
    ":private_verification_tokens_public_key",
    "//net",
  ]
}

source_set("private_verification_tokens_issuer_config_unittest") {
  testonly = true
  sources = [ "private_verification_tokens_issuer_config_unittest.cc" ]
  deps = [
    ":private_verification_tokens_issuer_config",
    ":private_verification_tokens_parameters",
    "//base",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}

# ATHM (Anonymous Tokens with Hidden Metadata): Crubit bindings over
# //third_party/anonymous_tokens:athm and the C++ that calls it.
if (enable_rust) {
  # Test issuer modeled on network::TestTrustTokenIssuer: holds the secret ATHM
  # key material and exposes issuer-side (Issue/Verify) and client-side
  # (request/finalize) operations over Crubit bindings.
  # This is to be used in tests only. Chrome does not need/use
  # issuer side capability.
  source_set("athm_test_issuer") {
    testonly = true
    sources = [
      "athm_test_issuer.cc",
      "athm_test_issuer.h",
    ]
    public_deps = [
      "//base",
      "//components/private_verification_tokens/common/athm_ffi:athm_ffi_bindings",
    ]
    deps = [
      ":private_verification_tokens_parameters",
      "//crypto",
      "//third_party/anonymous_tokens:athm_token_encodings_utils",
    ]
  }

  source_set("privacy_pass_athm_batch_request") {
    sources = [
      "privacy_pass_athm_batch_request.cc",
      "privacy_pass_athm_batch_request.h",
    ]
    deps = [
      ":private_verification_tokens_parameters",
      ":private_verification_tokens_public_key",
      "//crypto",
      "//third_party/anonymous_tokens:athm_token_encodings_utils",
    ]
    public_deps = [
      ":private_verification_tokens_issuer_config",
      "//base",
      "//components/private_verification_tokens/common/athm_ffi:athm_ffi_bindings",
    ]
  }

  source_set("privacy_pass_athm_batch_request_unittest") {
    testonly = true
    sources = [ "privacy_pass_athm_batch_request_unittest.cc" ]
    deps = [
      ":athm_test_issuer",
      ":privacy_pass_athm_batch_request",
      ":private_verification_tokens_issuer_config",
      ":private_verification_tokens_parameters",
      ":private_verification_tokens_public_key",
      "//base",
      "//testing/gmock",
      "//testing/gtest",
      "//third_party/anonymous_tokens:athm_token_encodings_utils",
      "//url",
    ]
  }

  source_set("athm_test_issuer_unittest") {
    testonly = true
    sources = [ "athm_test_issuer_unittest.cc" ]
    deps = [
      ":athm_test_issuer",
      ":privacy_pass_athm_batch_request",
      ":private_verification_tokens_issuer_config",
      ":private_verification_tokens_parameters",
      ":private_verification_tokens_public_key",
      "//base",
      "//crypto",
      "//testing/gmock",
      "//testing/gtest",
      "//third_party/anonymous_tokens:athm_token_encodings_utils",
      "//url",
    ]
  }
}