# Copyright 2015 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/features.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//printing/buildflags/buildflags.gni")

assert(enable_printing)

if (enable_print_media_l10n) {
  source_set("print_media_l10n") {
    sources = [
      "print_media_l10n.cc",
      "print_media_l10n.h",
    ]

    public_deps = [ "//printing/backend" ]

    deps = [
      "//base",
      "//base:i18n",
      "//components/strings:components_strings_grit",
      "//printing:printing_base",
      "//ui/base",
    ]
  }
}

static_library("common") {
  sources = [
    "cloud_print_cdd_conversion.cc",
    "cloud_print_cdd_conversion.h",
    "print_params.cc",
    "print_params.h",
  ]

  deps = [
    ":mojo_interfaces",
    "//base",
    "//components/cloud_devices/common",
    "//printing",
    "//printing/backend",
    "//printing/common",
    "//printing/mojom",
  ]

  if (is_linux) {
    deps += [
      "//build/config/linux/dbus:buildflags",
      "//ui/linux:linux_ui",
    ]
    sources += [
      "print_dialog_linux_factory.cc",
      "print_dialog_linux_factory.h",
    ]
    if (use_dbus) {
      sources += [
        "print_dialog_linux_portal.cc",
        "print_dialog_linux_portal.h",
      ]
      deps += [
        "//components/dbus",
        "//components/strings:components_strings_grit",
        "//dbus",
      ]
    }
  }
}

mojom("mojo_interfaces") {
  sources = [ "print.mojom" ]

  public_deps = [
    "//mojo/public/mojom/base",
    "//printing/mojom",
    "//ui/accessibility/mojom",
    "//ui/gfx/geometry/mojom",
  ]

  enabled_features = []
  if (enable_print_preview) {
    enabled_features += [ "enable_print_preview" ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [ "cloud_print_cdd_conversion_unittest.cc" ]
  deps = [
    ":common",
    "//base/test:test_support",
    "//printing/backend",
    "//printing/backend:test_support",
    "//testing/gtest",
    "//ui/gfx/geometry",
  ]

  if (is_chromeos) {
    deps += [ "//printing" ]
  }

  if (enable_print_media_l10n) {
    sources += [ "print_media_l10n_unittest.cc" ]
    deps += [ ":print_media_l10n" ]
  }

  if (is_linux && use_dbus) {
    sources += [ "print_dialog_linux_portal_unittest.cc" ]
    deps += [
      "//components/dbus",
      "//dbus",
      "//dbus:test_support",
      "//printing",
      "//testing/gmock",
      "//ui/base",
    ]
  }

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}