# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//third_party/protobuf/proto_library.gni")

proto_library("prediction_service_messages_proto") {
  sources = [
    "permissions_aiv4_model_metadata.proto",
    "prediction_model_metadata.proto",
    "prediction_service_messages.proto",
  ]
}

source_set("prediction_service") {
  _configs = configs
  configs = []
  configs = [ "//third_party/tflite:tflite_shim_config" ] + _configs
  sources = [
    "permission_ui_selector.cc",
    "permission_ui_selector.h",
    "permissions_ai_encoder_base.cc",
    "permissions_ai_encoder_base.h",
    "permissions_aiv4_executor.cc",
    "permissions_aiv4_executor.h",
    "permissions_aiv4_handler.cc",
    "permissions_aiv4_handler.h",
    "prediction_common.cc",
    "prediction_common.h",
    "prediction_model_executor.cc",
    "prediction_model_executor.h",
    "prediction_model_handler.cc",
    "prediction_model_handler.h",
    "prediction_request_features.h",
    "prediction_service.cc",
    "prediction_service.h",
    "prediction_service_base.h",
    "prediction_signature_model_executor.cc",
    "prediction_signature_model_executor.h",
  ]
  deps = [
    "//components/keyed_service/content",
    "//components/passage_embeddings/core",
    "//components/permissions:permissions_common",
    "//components/version_info",
    "//content/public/browser",
    "//services/network/public/cpp",
    "//skia",
    "//third_party/protobuf:protobuf_lite",
    "//third_party/tflite:tflite_public_headers",
    "//third_party/tflite_support",
    "//third_party/tflite_support:tflite_support_proto",
  ]
  public_deps = [
    ":prediction_service_messages_proto",
    "//components/optimization_guide/core",
    "//components/optimization_guide/proto:optimization_guide_proto",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "permissions_aiv4_handler_unittest.cc",
    "prediction_service_unittest.cc",
  ]
  deps = [
    ":prediction_service",
    "//base",
    "//base/test:test_support",
    "//components/optimization_guide/core:test_support",
    "//components/permissions:permissions_common",
    "//components/permissions:test_support",
    "//services/network:test_support",
    "//services/network/public/cpp",
    "//testing/gtest",
    "//third_party/protobuf:protobuf_lite",
    "//ui/gfx",
  ]
  data = [ "//components/test/data/permissions/" ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}