# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//components/guest_view/buildflags/buildflags.gni")
import("//mojo/public/tools/bindings/mojom.gni")
import("//tools/grit/grit_rule.gni")

assert(enable_guest_view)

static_library("slim_web_view") {
  sources = [
    "request_utils.cc",
    "request_utils.h",
    "slim_web_view_constants.cc",
    "slim_web_view_constants.h",
    "slim_web_view_guest.cc",
    "slim_web_view_guest.h",
    "slim_web_view_navigation_throttle.cc",
    "slim_web_view_navigation_throttle.h",
    "slim_web_view_permission_helper.cc",
    "slim_web_view_permission_helper.h",
    "slim_web_view_url_loader_factory_interceptor.cc",
    "slim_web_view_url_loader_factory_interceptor.h",
  ]

  deps = [
    ":mojo_bindings",
    ":strings",
    "//base",
    "//components/guest_view/browser",
    "//components/url_pattern",
    "//components/zoom",
    "//content/public/browser",
    "//content/public/common",
    "//net",
    "//third_party/blink/public:blink_headers",
    "//url",
  ]
}

static_library("page_handler") {
  sources = [
    "slim_web_view_page_handler.cc",
    "slim_web_view_page_handler.h",
    "slim_web_view_page_handler_factory.cc",
    "slim_web_view_page_handler_factory.h",
  ]

  public_deps = [ ":mojo_bindings" ]

  deps = [
    ":slim_web_view",
    "//components/guest_view/browser",
    "//content/public/browser",
  ]
}

mojom("mojo_bindings") {
  sources = [ "slim_web_view.mojom" ]
  webui_module_path = "/shared/guest_view"

  deps = [
    "//mojo/public/mojom/base",
    "//ui/gfx/geometry/mojom",
    "//url/mojom:url_mojom_gurl",
  ]
}

grit_strings("strings") {
  source = "strings/slim_web_view_strings.grd"
  inputs = process_file_template(
          xtb_locales,
          [ "strings/slim_web_view_strings_{{source_name_part}}.xtb" ])
  outputs = [ "grit/slim_web_view_strings.h" ]
  output_prefix = "slim_web_view_strings_"
}

source_set("unit_tests") {
  testonly = true

  sources = [ "slim_web_view_permission_helper_unittest.cc" ]

  deps = [
    ":mojo_bindings",
    ":slim_web_view",
    "//base",
    "//base/test:test_support",
    "//components/guest_view/browser",
    "//components/guest_view/browser:test_support",
    "//content/public/browser",
    "//content/test:test_support",
    "//testing/gtest",
  ]
}