# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//components/enterprise/buildflags/buildflags.gni")

source_set("watermarking") {
  configs += [ "//components/enterprise:extra_warnings" ]

  sources = [
    "watermark.cc",
    "watermark.h",
  ]

  public_deps = [
    "//skia",
    "//ui/gfx",
  ]
}

source_set("watermarking_handler") {
  sources = []
  deps = []

  if (enterprise_watermark) {
    sources += [
      "watermark_style_policy_handler.cc",
      "watermark_style_policy_handler.h",
    ]

    deps += [
      "//components/enterprise/connectors/core",
      "//components/policy/core/browser",
      "//components/policy/core/common",
      "//components/prefs",
      "//components/strings:components_strings_grit",
    ]
  }
}

source_set("unit_tests") {
  testonly = true
  configs += [ "//components/enterprise:extra_warnings" ]

  sources = []
  if (!is_ios) {
    sources += [ "watermark_unittest.cc" ]
  }

  if (enterprise_watermark) {
    sources += [ "watermark_style_policy_handler_unittest.cc" ]
  }

  data = [
    "//components/test/data/enterprise/watermark_dark.png",
    "//components/test/data/enterprise/watermark_light.png",
  ]

  deps = [
    "//components/enterprise/connectors/core",
    "//components/policy/core/browser",
    "//components/policy/core/common",
    "//components/prefs",
    "//testing/gtest",
  ]

  if (enterprise_watermark) {
    deps += [ ":watermarking_handler" ]
  }

  if (!is_ios) {
    deps += [
      ":watermarking",
      "//cc:test_support",
      "//cc/paint",
    ]
  }
}

source_set("watermark_test_utils") {
  testonly = true
  configs += [ "//components/enterprise:extra_warnings" ]

  sources = [
    "watermark_test_utils.cc",
    "watermark_test_utils.h",
  ]

  deps = [ "//components/enterprise/watermarking" ]

  public_deps = [
    "//components/enterprise/watermarking/mojom",
    "//skia",
  ]
}