# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//chrome/android/features/android_library_factory_tmpl.gni")
import("//third_party/jni_zero/jni_zero.gni")

source_set("android") {
  sources = [
    "bottom_sheet_feature_map.cc",
    "features.cc",
    "features.h",
  ]
  deps = [
    ":bottomsheet_jni_headers",
    "//base",
  ]
}

android_library("java") {
  srcjar_deps = [ ":bottomsheet_jni_headers" ]
  sources = [
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetContent.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetController.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetControllerProvider.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetFeatureMap.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetListViewBase.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetObserver.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetRecyclerScrollListener.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/ExpandedSheetHelper.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/ItemDividerBase.java",
  ]

  deps = [
    ":java_resources",
    "//base:base_java",
    "//components/browser_ui/styles/android:java",
    "//components/browser_ui/widget/android:java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_appcompat_appcompat_resources_java",
    "//third_party/androidx:androidx_core_core_java",
    "//third_party/androidx:androidx_recyclerview_recyclerview_java",
    "//third_party/jni_zero:jni_zero_java",
    "//ui/accessibility:ax_base_java",
    "//ui/android:ui_android_features_java",
    "//ui/android:ui_java",
  ]
  resources_package = "org.chromium.components.browser_ui.bottomsheet"
}

android_resources("java_resources") {
  sources = [
    "java/res/drawable/bottom_sheet_desktop_background.xml",
    "java/res/layout/bottom_sheet.xml",
    "java/res/layout/bottom_sheet_desktop.xml",
    "java/res/values/colors.xml",
    "java/res/values/dimens.xml",
  ]

  deps = [
    "//components/browser_ui/strings/android:browser_ui_strings_grd",
    "//components/browser_ui/widget/android:java_resources",
  ]
}

# The only dependent on this code outside of this component should be glue.
android_library("manager_java") {
  sources = [ "java/src/org/chromium/components/browser_ui/bottomsheet/ManagedBottomSheetController.java" ]

  deps = [
    ":java",
    "//components/browser_ui/desktop_windowing/android:java",
    "//components/browser_ui/widget/android:java",
    "//ui/android:ui_full_java",
  ]
}

android_library_factory("factory_java") {
  sources = [ "internal/java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetControllerFactory.java" ]

  deps = [
    ":java",
    ":manager_java",
    "//base:base_java",
    "//components/browser_ui/desktop_windowing/android:java",
    "//components/browser_ui/widget/android:java",
    "//ui/android:ui_full_java",
    "//ui/android:ui_utils_java",
  ]
}

generate_jni("bottomsheet_jni_headers") {
  sources = [
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetControllerProvider.java",
    "java/src/org/chromium/components/browser_ui/bottomsheet/BottomSheetFeatureMap.java",
  ]
}