# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//third_party/jni_zero/jni_zero.gni")

generate_jni("accessibility_jni_headers") {
  sources = [
    "java/src/org/chromium/components/browser_ui/accessibility/FontSizePrefs.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomMetrics.java",
  ]
}

source_set("android") {
  sources = [
    "font_size_prefs_android.cc",
    "font_size_prefs_android.h",
    "page_zoom_metrics.cc",
    "page_zoom_metrics.h",
  ]
  deps = [
    ":accessibility_jni_headers",
    "//base",
    "//components/prefs",
    "//components/user_prefs",
    "//content/public/browser",
    "//services/metrics/public/cpp:ukm_builders",
  ]
}

# Constants only target without dependencies to allow embedders to only include
# relevant code.
android_library("constants_java") {
  sources = [ "java/src/org/chromium/components/browser_ui/accessibility/AccessibilityConstants.java" ]
}

android_library("lib_java") {
  srcjar_deps = [ ":accessibility_jni_headers" ]
  sources = [
    "java/src/org/chromium/components/browser_ui/accessibility/AccessibilitySettings.java",
    "java/src/org/chromium/components/browser_ui/accessibility/AccessibilitySettingsDelegate.java",
    "java/src/org/chromium/components/browser_ui/accessibility/DeviceAccessibilitySettingsHandler.java",
    "java/src/org/chromium/components/browser_ui/accessibility/FontSizePrefs.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarCoordinator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarCoordinatorDelegate.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarMediator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarViewBinder.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomIndicatorCoordinator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomIndicatorMediator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomIndicatorViewBinder.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomManager.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomManagerDelegate.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomMenuItemCoordinator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomMenuItemMediator.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomMetrics.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomPreference.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomProperties.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomSeekbarPreference.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomSliderPreference.java",
    "java/src/org/chromium/components/browser_ui/accessibility/ZoomEventsObserver.java",
  ]

  deps = [
    ":java_resources",
    ":page_zoom_utils_java",
    "//base:base_java",
    "//base:supplier_java",
    "//build/android:build_java",
    "//components/browser_ui/bottomsheet/android:java",
    "//components/browser_ui/settings/android:java",
    "//components/browser_ui/site_settings/android:java",
    "//components/browser_ui/styles/android:java",
    "//components/browser_ui/widget/android:java",
    "//components/cached_flags:java",
    "//components/dom_distiller/core/android:dom_distiller_core_java",
    "//components/omnibox/common:features_java",
    "//components/prefs/android:java",
    "//components/user_prefs/android:java",
    "//content/public/android:content_full_java",
    "//content/public/android:content_main_dex_java",
    "//third_party/android_deps:material_design_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_core_core_java",
    "//third_party/androidx:androidx_fragment_fragment_java",
    "//third_party/androidx:androidx_preference_preference_java",
    "//third_party/jni_zero:jni_zero_java",
    "//ui/accessibility:ax_base_java",
    "//ui/android:ui_android_features_java",
    "//ui/android:ui_no_recycler_view_java",
    "//url:url_java",
  ]
  resources_package = "org.chromium.components.browser_ui.accessibility"
}

android_library("page_zoom_utils_java") {
  sources = [
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomUma.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomUtils.java",
  ]

  deps = [
    ":constants_java",
    "//base:base_java",
    "//base:tristate_java",
    "//content/public/android:content_full_java",
    "//content/public/android:content_main_dex_java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_preference_preference_java",
    "//third_party/jni_zero:jni_zero_java",
    "//ui/android:ui_no_recycler_view_java",
  ]
}

android_resources("java_resources") {
  sources = [
    "java/res/anim/slide_out_child_bottom.xml",
    "java/res/drawable/ic_zoom.xml",
    "java/res/drawable/page_zoom_background.xml",
    "java/res/drawable/page_zoom_ripple.xml",
    "java/res/layout/page_zoom_indicator_view.xml",
    "java/res/layout/page_zoom_legacy_preference.xml",
    "java/res/layout/page_zoom_preference.xml",
    "java/res/layout/page_zoom_slider.xml",
    "java/res/layout/page_zoom_view.xml",
    "java/res/layout/text_size_contrast_slider.xml",
    "java/res/values/dimens.xml",
    "java/res/values/styles.xml",
    "java/res/xml/accessibility_preferences.xml",
  ]

  deps = [
    "//components/browser_ui/strings/android:browser_ui_strings_grd",
    "//components/browser_ui/styles/android:java_resources",
    "//third_party/androidx:androidx_preference_preference_java",
  ]
}

robolectric_library("junit") {
  testonly = true

  sources = [
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarCoordinatorUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarMediatorUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomIndicatorCoordinatorUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomIndicatorMediatorUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomManagerUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomMenuItemMediatorUnitTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomUtilsUnitTest.java",
  ]

  deps = [
    ":lib_java",
    ":page_zoom_utils_java",
    "//base:base_java",
    "//base:base_java_test_support",
    "//base:base_junit_test_support",
    "//components/browser_ui/bottomsheet/android:java",
    "//content/public/android:content_full_java",
    "//content/public/android:content_main_dex_java",
    "//content/public/android:content_main_dex_jni_java",
    "//content/public/common:common_java",
    "//third_party/android_deps:material_design_java",
    "//third_party/androidx:androidx_appcompat_appcompat_java",
    "//third_party/androidx:androidx_test_core_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/hamcrest:hamcrest_core_java",
    "//third_party/hamcrest:hamcrest_library_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/android:ui_no_recycler_view_java",
    "//url:url_java",
  ]
}

android_library("unit_device_javatests") {
  testonly = true
  resources_package = "org.chromium.components.browser_ui.accessibility"

  sources = [
    "java/src/org/chromium/components/browser_ui/accessibility/AccessibilitySettingsPageZoomTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/AccessibilitySettingsTest.java",
    "java/src/org/chromium/components/browser_ui/accessibility/PageZoomBarViewTest.java",
  ]

  deps = [
    ":java_resources",
    ":lib_java",
    ":page_zoom_utils_java",
    "//base:base_java_test_support",
    "//base:callback_java",
    "//base:supplier_java",
    "//base:tasks_java",
    "//components/browser_ui/bottomsheet/android:java",
    "//components/browser_ui/settings/android:java",
    "//components/browser_ui/settings/android:test_support_java",
    "//components/dom_distiller/core/android:dom_distiller_core_java",
    "//components/prefs/android:java",
    "//components/user_prefs/android:java",
    "//content/public/android:content_java",
    "//content/public/android:content_main_dex_jni_java",
    "//content/public/common:common_java",
    "//content/public/test/android:content_java_test_support",
    "//third_party/android_deps:espresso_java",
    "//third_party/android_deps:material_design_java",
    "//third_party/androidx:androidx_preference_preference_java",
    "//third_party/androidx:androidx_test_monitor_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/hamcrest:hamcrest_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/accessibility:ax_base_java",
    "//ui/accessibility:ui_accessibility_test_support_java",
    "//ui/android:ui_java_test_support",
    "//ui/android:ui_no_recycler_view_java",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "page_zoom_metrics_unittest.cc" ]
  deps = [
    "//components/browser_ui/accessibility/android",
    "//components/ukm:test_support",
    "//testing/gtest",
  ]
}