# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//chromeos/ash/experiences/extensions/api/api_sources.gni")
import("//extensions/buildflags/buildflags.gni")
import("//extensions/common/api/schema.gni")
import("//tools/json_schema_compiler/json_features.gni")
import("//tools/json_schema_compiler/json_schema_api.gni")

assert(is_chromeos)
assert(enable_extensions_core)

################################################################################
# Public Targets

group("api") {
  public_deps = [
    ":generated_api_json_strings",
    ":generated_api_types",
  ]
}

group("extensions_features") {
  public_deps = [
    ":api_features",
    ":manifest_features",
    ":permission_features",
  ]
}

################################################################################
# Private Targets

generated_json_strings("generated_api_json_strings") {
  sources = chromeos_extensions_api_schema_sources
  configs = [ "//build/config:precompiled_headers" ]
  bundle_name = "ChromeOS"
  schema_include_rules = chromeos_extensions_api_schema_include_rules

  root_namespace = chromeos_extensions_api_root_namespace
  deps = [ "//extensions/common/api" ]
  inputs = extensions_api_schema_files + extensions_types_only_schema_files

  visibility = [ ":api" ]
}

generated_types("generated_api_types") {
  sources = chromeos_extensions_api_schema_sources
  configs = [ "//build/config:precompiled_headers" ]
  schema_include_rules = chromeos_extensions_api_schema_include_rules

  root_namespace = chromeos_extensions_api_root_namespace
  deps = [ "//extensions/common/api" ]
  inputs = extensions_api_schema_files + extensions_types_only_schema_files

  visibility = [ ":api" ]
}

json_features("api_features") {
  feature_type = "APIFeature"
  method_name = "AddChromeOSAPIFeatures"
  sources = [ "_api_features.json" ]
  inputs = [ "_api_features.override.json" ]
  visibility = [ ":extensions_features" ]
}

json_features("permission_features") {
  feature_type = "PermissionFeature"
  method_name = "AddChromeOSPermissionFeatures"
  sources = [ "_permission_features.json" ]
  inputs = [ "_permission_features.override.json" ]
  visibility = [ ":extensions_features" ]
}

json_features("manifest_features") {
  feature_type = "ManifestFeature"
  method_name = "AddChromeOSManifestFeatures"
  sources = [ "_manifest_features.json" ]
  inputs = [ "_manifest_features.override.json" ]
  visibility = [ ":extensions_features" ]
}