# Copyright 2019 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//extensions/buildflags/buildflags.gni")

source_set("profiler") {
  public = [
    "chrome_thread_group_profiler_client.h",
    "chrome_thread_profiler_client.h",
    "core_unwinders.h",
    "main_thread_stack_sampling_profiler.h",
    "process_type.h",
    "thread_profiler_configuration.h",
  ]

  sources = [
    "chrome_thread_group_profiler_client.cc",
    "chrome_thread_profiler_client.cc",
    "main_thread_stack_sampling_profiler.cc",
    "process_type.cc",
    "thread_profiler_configuration.cc",
    "thread_profiler_platform_configuration.cc",
    "thread_profiler_platform_configuration.h",
  ]

  configs += [ "//build/config/compiler:wexit_time_destructors" ]

  deps = [
    "//base",
    "//build:branding_buildflags",
    "//chrome/common:channel_info",
    "//chrome/common:non_code_constants",
    "//components/metrics",
    "//components/metrics:call_stack_profile_builder",
    "//components/metrics/public/mojom:call_stack_mojo_bindings",
    "//components/sampling_profiler",
    "//components/version_info",
    "//content/public/common",
    "//extensions/buildflags",
    "//third_party/abseil-cpp:absl",
  ]

  if (is_android) {
    deps += [
      "//base:native_unwinder_android",
      "//chrome/android/features/stack_unwinder/public:native",
      "//chrome/android/modules/stack_unwinder/public:module",
    ]
    public += [ "native_unwinder_android_map_delegate_impl.h" ]
    sources += [
      "core_unwinders_android.cc",
      "native_unwinder_android_map_delegate_impl.cc",
    ]
  } else {
    sources += [ "core_unwinders.cc" ]
  }

  if (enable_extensions_core) {
    deps += [ "//extensions/common" ]
  }

  friend = [ ":unit_tests" ]
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "process_type_unittest.cc",
    "thread_profiler_configuration_unittest.cc",
    "thread_profiler_platform_configuration_unittest.cc",
  ]

  deps = [
    ":profiler",
    "//base/test:test_support",
    "//build:branding_buildflags",
    "//chrome/common:channel_info",
    "//chrome/common:non_code_constants",
    "//components/metrics",
    "//components/metrics:call_stack_profile_builder",
    "//components/sampling_profiler",
    "//components/version_info",
    "//content/public/common",
    "//extensions/buildflags",
  ]

  if (is_android) {
    sources += [ "core_unwinders_android_unittest.cc" ]
  }

  if (enable_extensions_core) {
    deps += [ "//extensions/common" ]
  }
}