# Copyright 2023 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# This whole package is android only
assert(is_android)

import("//build/config/android/config.gni")
import("//build/config/android/rules.gni")
import("//third_party/jni_zero/jni_zero.gni")

source_set("wallet_android") {
  public = [ "boarding_pass_detector.h" ]

  sources = [
    "boarding_pass_bridge.cc",
    "boarding_pass_detector.cc",
  ]

  public_deps = [
    "//base",
    "//chrome/common/wallet:mojo_bindings",
    "//mojo/public/cpp/bindings",
  ]

  deps = [
    ":jni_headers",
    "//base",
    "//chrome/common:chrome_features",
    "//content/public/browser",
    "//services/service_manager/public/cpp",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "boarding_pass_detector_unittest.cc" ]

  deps = [
    ":wallet_android",
    "//base/test:test_support",
    "//chrome/common:chrome_features",
    "//chrome/common/wallet:mojo_bindings",
    "//mojo/public/cpp/bindings",
    "//testing/gtest",
  ]
}

android_library("java") {
  sources = [
    "java/src/org/chromium/chrome/browser/wallet/BoardingPassBridge.java",
    "java/src/org/chromium/chrome/browser/wallet/BoardingPassController.java",
  ]
  srcjar_deps = [ ":jni_headers" ]
  resources_package = "org.chromium.chrome.browser.wallet"
  deps = [
    "//base:base_java",
    "//chrome/browser/flags:java",
    "//chrome/browser/tab:java",
    "//content/public/android:content_java",
    "//third_party/jni_zero:jni_zero_java",
    "//url:gurl_java",
  ]
}

generate_jni("jni_headers") {
  sources =
      [ "java/src/org/chromium/chrome/browser/wallet/BoardingPassBridge.java" ]
}

robolectric_library("junit") {
  sources = [ "javatests/src/org/chromium/chrome/browser/wallet/BoardingPassControllerTest.java" ]
  deps = [
    "//base:base_java",
    "//base:base_java_test_support",
    "//base:base_junit_test_support",
    "//chrome/browser/flags:java",
    "//chrome/browser/tab:java",
    "//chrome/browser/wallet/android:java",
    "//content/public/android:content_java",
    "//third_party/android_deps:guava_android_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//url:url_java",
  ]
}