# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

assert(!is_android && !is_chromeos)

source_set("default_browser_modal") {
  sources = [
    "default_browser_modal_dialog_delegate.cc",
    "default_browser_modal_dialog_delegate.h",
    "default_browser_modal_handler.cc",
    "default_browser_modal_handler.h",
    "default_browser_modal_ui.cc",
    "default_browser_modal_ui.h",
  ]

  public_deps = [ "//base" ]

  deps = [
    "//chrome/app/theme:chrome_unscaled_resources",
    "//chrome/browser/default_browser",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/resources/default_browser/default_browser_modal:resources",
    "//chrome/browser/ui/dialogs",
    "//chrome/browser/ui/startup/default_browser_prompt",
    "//chrome/browser/ui/views/web_dialogs",
    "//chrome/browser/ui/webui:theme_source",
    "//chrome/browser/ui/webui/default_browser:modal_mojo_bindings",
    "//chrome/browser/ui/webui/top_chrome",
    "//chrome/common",
    "//content/public/browser",
    "//ui/base/interaction",
    "//ui/gfx",
    "//ui/views",
    "//ui/views/controls/webview",
    "//ui/web_dialogs",
    "//ui/webui",
    "//url",
  ]
}

mojom("modal_mojo_bindings") {
  sources = [ "default_browser_modal.mojom" ]
  webui_module_path = "/"
}

if (is_win) {
  mojom("visual_guided_setter_mojo_bindings") {
    sources = [ "visual_guided_setter.mojom" ]
    webui_module_path = "/"
    public_deps = [ "//ui/gfx/geometry/mojom" ]
  }

  source_set("visual_guided_setter") {
    sources = [
      "guided_setter_overlay_window_win.cc",
      "guided_setter_overlay_window_win.h",
      "settings_window_finder_win.cc",
      "settings_window_finder_win.h",
      "visual_guided_setter_controller_win.cc",
      "visual_guided_setter_controller_win.h",
      "visual_guided_setter_layout_utils.cc",
      "visual_guided_setter_layout_utils.h",
      "visual_guided_setter_page_handler.cc",
      "visual_guided_setter_page_handler.h",
      "visual_guided_setter_ui.cc",
      "visual_guided_setter_ui.h",
    ]

    public_deps = [
      ":visual_guided_setter_mojo_bindings",
      "//base",
      "//ui/gfx",
    ]

    deps = [
      "//chrome/app/theme:chrome_unscaled_resources",
      "//chrome/browser/default_browser",
      "//chrome/browser/profiles:profile",
      "//chrome/browser/resources/default_browser/visual_guided_setter:resources",
      "//chrome/browser/ui/dialogs",
      "//chrome/browser/ui/webui:theme_source",
      "//chrome/browser/ui/webui/top_chrome",
      "//chrome/common",
      "//content/public/browser",
      "//ui/base/interaction",
      "//ui/display",
      "//ui/gfx/geometry",
      "//ui/views",
      "//ui/web_dialogs",
      "//ui/webui",
      "//url",
    ]
  }

  source_set("unit_tests") {
    testonly = true

    sources = [
      "guided_setter_overlay_window_win_unittest.cc",
      "settings_window_finder_win_unittest.cc",
      "visual_guided_setter_controller_win_unittest.cc",
      "visual_guided_setter_layout_utils_unittest.cc",
    ]

    deps = [
      ":visual_guided_setter",
      "//base",
      "//base/test:test_support",
      "//chrome/browser/default_browser",
      "//chrome/test:test_support",
      "//content/test:test_support",
      "//testing/gtest",
      "//ui/gfx",
      "//ui/views",
      "//ui/views:test_support",
    ]
  }

  source_set("pixel_tests") {
    testonly = true

    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

    sources = [ "default_browser_modal_pixeltest.cc" ]

    deps = [
      ":default_browser_modal",
      "//base",
      "//chrome/browser/default_browser",
      "//chrome/browser/ui",
      "//chrome/browser/ui/navigator",
      "//chrome/browser/ui/tabs:tab_strip_model_observer",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//content/public/browser",
      "//content/test:test_support",
      "//ui/base/interaction",
      "//ui/gfx",
    ]
  }
}

source_set("browser_tests") {
  testonly = true

  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = []
  deps = []

  if (is_win) {
    sources += [ "visual_guided_setter_ui_browsertest.cc" ]

    deps += [
      ":visual_guided_setter",
      "//chrome/test:test_support_ui",
    ]
  }
}