# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(!is_android)

import("//mojo/public/tools/bindings/mojom.gni")

mojom("mojo_bindings") {
  sources = [ "data_sharing.mojom" ]
  public_deps = [
    "//components/data_sharing/public/protocol:mojo_bindings",
    "//mojo/public/mojom/base",
  ]
  webui_module_path = "/"
}

source_set("data_sharing") {
  public = [
    "data_sharing_page_handler.h",
    "data_sharing_ui.h",
  ]
  public_deps = [
    ":mojo_bindings",
    "//base",
    "//chrome/browser/ui/webui/top_chrome",
    "//google_apis",
    "//mojo/public/cpp/bindings",
  ]
}

source_set("impl") {
  sources = [
    "data_sharing_page_handler.cc",
    "data_sharing_ui.cc",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]

  deps = [
    ":data_sharing",
    "//chrome/app:generated_resources",
    "//chrome/browser/metrics",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/resources/data_sharing:resources",
    "//chrome/browser/signin",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/tabs/saved_tab_groups",
    "//chrome/browser/ui/views/data_sharing",
    "//chrome/browser/ui/webui:favicon_source",
    "//chrome/browser/ui/webui:theme_source",
    "//chrome/browser/ui/webui:webui_util",
    "//chrome/common",
    "//components/data_sharing/public",
    "//components/favicon_base",
    "//components/saved_tab_groups/public",
    "//components/signin/public/identity_manager",
    "//components/strings:components_strings",
    "//components/version_info",
    "//content/public/browser",
    "//ui/base",
    "//ui/webui",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "data_sharing_page_handler_unittest.cc" ]
  deps = [
    ":data_sharing",
    "//base",
    "//base/test:test_support",
    "//chrome/test:test_support",
    "//content/test:test_support",
    "//testing/gtest",
  ]
}