# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//mojo/public/tools/bindings/mojom.gni")

mojom("mojo_bindings") {
  sources = [ "context_hub.mojom" ]
  webui_module_path = "/"
  public_deps = [
    "//mojo/public/mojom/base",
    "//url/mojom:url_mojom_gurl",
  ]
  cpp_typemaps = [
    {
      types = [
        {
          mojom = "browser.context_hub.mojom.AutoTodoStatus"
          cpp = "::context_hub::AutoTodoEntry::Status"
        },
        {
          mojom = "browser.context_hub.mojom.AutoTodoGroup"
          cpp = "::context_hub::ThirdPartyData::GroupType"
        },
        {
          mojom = "browser.context_hub.mojom.GmailReference"
          cpp = "::context_hub::SourceReference"
        },
        {
          mojom = "browser.context_hub.mojom.SourceReference"
          cpp = "::context_hub::SourceReference"
        },
        {
          mojom = "browser.context_hub.mojom.FirstPartyData"
          cpp = "::context_hub::FirstPartyData"
        },
        {
          mojom = "browser.context_hub.mojom.ThirdPartyData"
          cpp = "::context_hub::ThirdPartyData"
        },
        {
          mojom = "browser.context_hub.mojom.AutoTodoData"
          cpp = "::std::variant<::context_hub::FirstPartyData, ::context_hub::ThirdPartyData>"
        },
        {
          mojom = "browser.context_hub.mojom.AutoTodoItem"
          cpp = "::context_hub::AutoTodoEntry"
        },
      ]
      traits_headers = [ "context_hub_mojom_traits.h" ]
      traits_sources = [ "context_hub_mojom_traits.cc" ]
      traits_deps = [
        "//base",
        "//chrome/browser/context_hub/auto_todos",
        "//mojo/public/mojom/base",
        "//third_party/abseil-cpp:absl",
        "//url",
      ]
    },
  ]
}

source_set("context_hub_page_handler") {
  sources = [
    "context_hub_page_handler.cc",
    "context_hub_page_handler.h",
  ]

  public_deps = [
    ":mojo_bindings",
    "//base",
    "//content/public/browser",
    "//mojo/public/cpp/bindings",
    "//ui/webui",
  ]

  deps = [
    "//chrome/browser/context_hub",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui/browser_window",
    "//chrome/common",
    "//components/sessions",
  ]

  if (!is_android) {
    sources += [
      "context_hub_tab_provider_desktop.cc",
      "context_hub_tab_provider_desktop.h",
    ]
    deps += [
      "//chrome/browser/ui",
      "//chrome/browser/ui/tabs:tab_strip",
      "//chrome/browser/ui/tabs/saved_tab_groups",
      "//components/saved_tab_groups/public",
      "//ui/base",
    ]
  }
}

source_set("context_hub") {
  sources = [
    "context_hub_ui.cc",
    "context_hub_ui.h",
  ]

  public_deps = [
    ":context_hub_page_handler",
    "//base",
    "//content/public/browser",
    "//ui/webui",
  ]

  deps = [
    "//chrome/browser/context_hub:features",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/resources/context_hub:resources",
    "//chrome/common",
  ]

  if (!is_android) {
    deps += [ "//chrome/browser/ui/webui:favicon_source" ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [ "context_hub_page_handler_unittest.cc" ]
  deps = [
    ":context_hub_page_handler",
    "//base/test:test_support",
    "//chrome/browser/context_hub",
    "//chrome/browser/optimization_guide:test_support",
    "//chrome/browser/personal_context",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/test:test_support",
    "//components/personal_context/core:test_support",
    "//components/personal_context/proto:personal_context_proto",
    "//components/saved_tab_groups/test_support",
    "//content/test:test_support",
    "//mojo/public/cpp/test_support:test_utils",
    "//testing/gmock",
    "//testing/gtest",
  ]

  if (!is_android) {
    sources += [ "context_hub_tab_provider_desktop_unittest.cc" ]
    deps += [
      "//chrome/browser/ui:test_support",
      "//chrome/browser/ui/tabs:test_support",
      "//ui/base:test_support",
    ]
  }
}