# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/chromeos/args.gni")
import("//build/config/ui.gni")

assert(toolkit_views)

source_set("hovercard_helpers") {
  public = [
    "fade_label_view.h",
    "fade_view.h",
    "filename_elider.h",
    "tab_hover_card_thumbnail_observer.h",
  ]

  sources = [
    "fade_label_view.cc",
    "filename_elider.cc",
    "tab_hover_card_thumbnail_observer.cc",
  ]

  public_deps = [
    "//base",
    "//chrome/browser/ui/thumbnails",
    "//ui/views",
  ]

  deps = [
    "//base:i18n",
    "//chrome/browser/ui/tabs",
    "//skia",
    "//ui/base",
    "//ui/gfx",
  ]
}

source_set("hovercard") {
  public = [
    "fade_footer_view.h",
    "hover_card_anchor_target.h",
    "tab_hover_card_bubble_view.h",
    "tab_hover_card_controller.h",
  ]

  public_deps = [
    ":hovercard_helpers",
    "//base",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/performance_controls",
    "//chrome/browser/ui/tabs:tab_enums",
    "//chrome/browser/ui/thumbnails",
    "//chrome/browser/ui/views:layout_provider",
    "//chrome/browser/ui/views/tabs:base",
    "//components/prefs",
    "//ui/base/metadata",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//ui/views",
  ]

  # TODO(crbug.com/451609048): Remove this circular dependency when the
  # following header gets componentized:
  # - c/b/ui/views/tabs/tab_slot_controller.h
  # (No allow_circular_includes_from entry belongs here -- the waiver that
  # makes this legal is declared on //chrome/browser/ui:ui, which is the
  # target that owns tab_slot_controller.h and depends on this target.)
}

source_set("impl") {
  sources = [
    "fade_footer_view.cc",
    "hover_card_anchor_target.cc",
    "tab_hover_card_bubble_view.cc",
    "tab_hover_card_controller.cc",
  ]

  deps = [
    ":hovercard",
    ":hovercard_helpers",
    "//base",
    "//chrome/app:generated_resources",
    "//chrome/app/vector_icons",
    "//chrome/browser:browser_process",
    "//chrome/browser/ui:layout_constants",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/color:color_headers",
    "//chrome/browser/ui/performance_controls",
    "//chrome/browser/ui/tabs",
    "//chrome/browser/ui/tabs:tab_strip",
    "//chrome/browser/ui/tabs/alert:tab_alert",
    "//chrome/browser/ui/tabs/saved_tab_groups",
    "//chrome/browser/ui/thumbnails",
    "//chrome/browser/ui/views",
    "//chrome/browser/ui/views:layout_provider",
    "//chrome/browser/ui/web_applications",
    "//chrome/common:constants",
    "//components/collaboration/public",
    "//components/prefs",
    "//components/strings",
    "//components/tabs:public",
    "//components/url_formatter",
    "//skia",
    "//ui/accessibility:ax_enums_mojo",
    "//ui/base",
    "//ui/base:features",
    "//ui/base/interaction",
    "//ui/base/mojom:ui_base_types",
    "//ui/color",
    "//ui/compositor",
    "//ui/events",
    "//ui/events/types:headers",
    "//ui/gfx",
    "//ui/gfx/geometry",
    "//ui/views",
    "//url",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]
}

source_set("test_support") {
  testonly = true
  sources = [
    "tab_hover_card_test_util.cc",
    "tab_hover_card_test_util.h",
  ]
  public_deps = [
    ":hovercard",
    "//base",
    "//chrome/browser/ui",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/tabs:features",
    "//chrome/browser/ui/views/frame",
    "//chrome/browser/ui/views/tabs/common:impl",
    "//ui/gfx:test_support",
    "//ui/views:test_support",
  ]
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [ "tab_hover_card_controller_browsertest.cc" ]
  deps = [
    ":hovercard",
    ":test_support",
    "//base",
    "//chrome/browser",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/performance_controls",
    "//chrome/browser/ui/tabs:features",
    "//chrome/browser/ui/thumbnails",
    "//chrome/browser/ui/views/tabs:base",
    "//chrome/browser/ui/views/tabs/common:impl",
    "//chrome/common:constants",
    "//chrome/test:test_support",
    "//content/test:test_support",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "tab_hover_card_bubble_view_unittest.cc" ]
  deps = [
    ":hovercard",
    ":hovercard_helpers",
    "//base",
    "//chrome/test/views",
    "//content/test:test_support",
    "//skia",
    "//testing/gtest",
    "//ui/gfx",
    "//ui/views:test_support",
  ]
}

if (!is_chromeos_device) {
  source_set("interactive_ui_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [ "tab_hover_card_controller_interactive_uitest.cc" ]
    deps = [
      ":hovercard",
      ":test_support",
      "//chrome/app:command_ids",
      "//chrome/browser/interstitials:test_support",
      "//chrome/browser/ui:browser_element_identifiers",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/interaction",
      "//chrome/browser/ui/performance_controls",
      "//chrome/browser/ui/performance_controls/test_support",
      "//chrome/browser/ui/tabs/saved_tab_groups",
      "//chrome/browser/ui/views/tabs/tab",
      "//chrome/browser/ui/views/tabs/tab:impl",
      "//chrome/browser/ui/views/test:test_support",
      "//chrome/browser/web_applications:web_applications_test_support",
      "//chrome/common",
      "//chrome/common:constants",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//chrome/test/interaction",
      "//components/collaboration/public",
      "//components/data_sharing/public",
      "//components/lookalikes/core:safety_tips",
      "//components/performance_manager",
      "//components/strings",
      "//components/tabs:public",
      "//content/public/browser",
      "//content/public/common",
      "//content/test:test_support",
      "//net",
      "//testing/gtest",
      "//ui/base:test_support",
      "//ui/display",
      "//ui/events",
      "//ui/events/types:headers",
      "//ui/gfx/geometry",
      "//ui/views",
      "//ui/views:test_support",
      "//url",
    ]

    if (is_chromeos) {
      deps += [ "//chrome/browser/ash/system_web_apps/test_support" ]
    }
  }
}