# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

assert(toolkit_views)

# tab_contents has no circular dependency back into //chrome/browser/ui:ui, so
# the public headers and implementation live in a single source_set. The Aura
# and Mac web contents view delegates are platform-specific.
source_set("tab_contents") {
  public = [ "chrome_web_contents_view_focus_helper.h" ]

  sources = [ "chrome_web_contents_view_focus_helper.cc" ]

  public_deps = [
    "//base",
    "//content/public/browser",
    "//ui/gfx",
    "//ui/views",
  ]

  deps = [
    "//chrome/browser/ui:browser_element_identifiers",
    "//chrome/browser/ui:sad_tab",
    "//chrome/browser/ui/tabs:tab_strip",
    "//components/tabs:public",
    "//components/web_modal",
    "//ui/base",
  ]

  if (use_aura) {
    public += [ "chrome_web_contents_view_delegate_views.h" ]
    sources += [ "chrome_web_contents_view_delegate_views.cc" ]
    public_deps += [
      "//components/renderer_context_menu",
      "//ui/base/clipboard",
    ]
    deps += [
      "//chrome/browser:defaults",
      "//chrome/browser/renderer_context_menu",
      "//chrome/browser/ui/aura/tab_contents",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/tab_contents",
      "//chrome/browser/ui/views/renderer_context_menu",
      "//content/public/common",
    ]
  }

  if (is_mac) {
    public += [ "chrome_web_contents_view_delegate_views_mac.h" ]
    sources += [ "chrome_web_contents_view_delegate_views_mac.mm" ]
    public_deps += [
      "//components/renderer_context_menu",
      "//ui/base/clipboard",
    ]
    deps += [
      "//chrome/browser/renderer_host:delegate",
      "//chrome/browser/ui:ui_features",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/cocoa",
      "//chrome/browser/ui/tab_contents",
      "//components/remote_cocoa/browser",
      "//content/public/common",
    ]
  }
}

source_set("unit_tests") {
  testonly = true

  sources = [ "chrome_web_contents_view_delegate_views_unittest.cc" ]

  deps = [
    ":tab_contents",
    "//chrome/test:test_support",
    "//content/test:test_support",
    "//testing/gtest",
    "//ui/views",
  ]
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [ "chrome_web_contents_view_delegate_browsertest.cc" ]

  deps = [
    ":tab_contents",
    "//chrome/test:test_support",
    "//content/test:test_support",
    "//testing/gtest",
    "//ui/views",
  ]
}