# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

assert(toolkit_views)

# safe_browsing has no circular dependency back into //chrome/browser/ui:ui, so
# the public headers and implementation live in a single target (no :impl
# split). It does form an allowed cycle with //chrome/browser/safe_browsing (the
# dialogs both use ChromePasswordProtectionService and are shown by that
# service); the reverse edge is the allow_circular_includes_from entry on
# //chrome/browser/safe_browsing.
source_set("safe_browsing") {
  public = [
    "password_reuse_modal_warning_dialog.h",
    "tailored_security_desktop_dialog_manager.h",
    "tailored_security_unconsented_modal.h",
  ]

  sources = [
    "password_reuse_modal_warning_dialog.cc",
    "tailored_security_desktop_dialog_manager.cc",
    "tailored_security_unconsented_modal.cc",
  ]

  public_deps = [
    "//base",
    "//components/password_manager/core/browser:metrics_util",
    "//components/safe_browsing/core/common:safe_browsing_prefs",
    "//content/public/browser",
    "//ui/base",
    "//ui/base/metadata",
    "//ui/views",
  ]

  deps = [
    "//chrome/app:generated_resources",
    "//chrome/app/theme:theme_resources",
    "//chrome/app/vector_icons",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/signin",
    "//chrome/browser/ui:chrome_pages",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/views:layout_provider",
    "//chrome/browser/ui/views/accessibility",
    "//components/constrained_window",
    "//components/safe_browsing/core/browser/password_protection:password_protection_metrics_util",
    "//components/safe_browsing/core/browser/tailored_security_service",
    "//components/safe_browsing/core/common",
    "//components/signin/public/identity_manager",
    "//components/strings:components_strings_grit",
    "//ui/base/mojom",
    "//ui/gfx",
  ]
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [
    "password_reuse_modal_warning_dialog_browsertest.cc",
    "tailored_security_desktop_dialog_manager_browsertest.cc",
  ]

  deps = [
    ":safe_browsing",
    "//chrome/browser/ui/tabs:tab_strip",
    "//chrome/browser/ui/test:dialog",
    "//chrome/test:test_support",
    "//components/safe_browsing/content/browser/password_protection",
    "//content/test:test_support",
    "//testing/gtest",
    "//ui/views",
  ]
}