# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

assert(toolkit_views)

# Split out from :promos below because it has no real dependency on
# //chrome/browser/ui/views/page_action (unlike ios_promo_bubble.{h,cc}),
# letting consumers that only need the plain IOSPromoTypeConfigs struct
# (e.g. //chrome/browser/ui/views/user_education) depend on it directly
# without pulling in page_action's dependency chain, which cycles back
# through toolbar/search/webui/new_tab_page into user_education.
source_set("constants") {
  public = [ "ios_promo_constants.h" ]
  sources = [ "ios_promo_constants.cc" ]
  public_deps = [ "//ui/base" ]
}

source_set("promos") {
  public = [ "ios_promo_bubble.h" ]
  sources = [ "ios_promo_bubble.cc" ]

  public_deps = [
    ":constants",
    "//base",
    "//ui/base",
    "//ui/views",
  ]

  deps = [
    "//chrome/app:branded_strings",
    "//chrome/app:generated_resources",
    "//chrome/app/theme:theme_resources",
    "//chrome/browser/desktop_to_mobile_promos:utils",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/color:color_headers",
    "//chrome/browser/ui/views:layout_provider",
    "//chrome/browser/ui/views/page_action",
    "//components/autofill/core/common",
    "//components/desktop_to_mobile_promos",
    "//components/prefs",
    "//components/qr_code_generator:bitmap_generator",
    "//components/strings",
    "//content/public/browser",
  ]
}

source_set("interactive_ui_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [ "ios_promo_bubble_interactive_uitest.cc" ]
  deps = [
    ":promos",
    "//base",
    "//base/test:test_support",
    "//chrome/browser/desktop_to_mobile_promos:utils",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui",
    "//chrome/browser/ui:browser_element_identifiers",
    "//chrome/browser/ui/actions:actions_headers",
    "//chrome/browser/ui/page_action:icon_type",
    "//chrome/browser/ui/views/frame:toolbar_button_provider",
    "//chrome/browser/ui/views/page_action",
    "//chrome/test:test_support",
    "//chrome/test:test_support_ui",
    "//components/autofill/core/common",
    "//components/desktop_to_mobile_promos",
    "//components/feature_engagement/public",
    "//components/feature_engagement/test:test_support",
    "//components/prefs",
    "//components/sync_preferences:features",
    "//content/test:test_support",
    "//ui/base",
  ]
}