# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_win || is_mac || is_linux || is_chromeos)

import("//build/config/ui.gni")

source_set("reopen_suppressor") {
  public = [ "webui_bubble_reopen_suppressor.h" ]
  sources = [ "webui_bubble_reopen_suppressor.cc" ]
  public_deps = [
    "//base",
    "//ui/views",
  ]
}

source_set("bubble") {
  sources = [
    "webui_bubble_dialog_view.cc",
    "webui_bubble_dialog_view.h",
    "webui_bubble_manager.cc",
    "webui_bubble_manager.h",
    "webui_bubble_manager_observer.h",
  ]
  public_deps = [
    "//base",
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser:primitives",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/views:close_bubble_on_tab_activation_helper",
    "//chrome/browser/ui/webui:webui_util",
    "//components/web_modal",
    "//content/public/browser",
    "//skia",
    "//ui/base/interaction",
    "//ui/views",
    "//ui/views/controls/webview",

    # TODO(crbug.com/353621219): Use target having
    # chrome/browser/ui/webui/top_chrome/webui_contents_wrapper.h instead after
    # fixing cyclic dependency for
    # obj/chrome/browser/ui/views/bubble/bubble/webui_bubble_manager.o.
    "//chrome/browser/ui:webui_name_variants",
  ]
  deps = [
    "//chrome/browser/ui/webui/top_chrome",
    "//components/input",
    "//ui/webui",
  ]

  if (use_aura) {
    sources += [
      "webui_bubble_event_handler_aura.cc",
      "webui_bubble_event_handler_aura.h",
    ]
    public_deps += [
      "//ui/events",
      "//ui/gfx/geometry",
    ]
    deps += [
      "//ui/aura",
      "//ui/display",
    ]
  }
}