# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

assert(toolkit_views)

source_set("saved_tab_groups") {
  public = [
    "saved_tab_group_bar.h",
    "saved_tab_group_button.h",
    "saved_tab_group_drag_data.h",
    "saved_tab_group_everything_menu.h",
    "saved_tab_group_overflow_button.h",
    "saved_tab_group_tabs_menu_model.h",
  ]

  public_deps = [
    "//base",
    "//chrome/browser/ui/tabs/saved_tab_groups",
    "//chrome/browser/ui/toolbar",
    "//chrome/browser/ui/views",
    "//components/saved_tab_groups/internal",
    "//components/saved_tab_groups/public",
    "//components/tab_groups",
    "//components/user_education/common",
    "//content/public/browser",
    "//ui/base",
    "//ui/base/clipboard:clipboard_types",
    "//ui/gfx/geometry",
    "//ui/menus",
    "//ui/views",
    "//url",
  ]
}

source_set("impl") {
  sources = [
    "saved_tab_group_bar.cc",
    "saved_tab_group_button.cc",
    "saved_tab_group_drag_data.cc",
    "saved_tab_group_everything_menu.cc",
    "saved_tab_group_overflow_button.cc",
    "saved_tab_group_tabs_menu_model.cc",
  ]

  deps = [
    ":saved_tab_groups",
    "//chrome/app:command_ids",
    "//chrome/app/vector_icons",
    "//chrome/browser/favicon",
    "//chrome/browser/tab_group_sync",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui:browser_element_identifiers",
    "//chrome/browser/ui:layout_constants",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui:view_ids",
    "//chrome/browser/ui/bookmarks",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/tabs:tab_strip",
    "//chrome/browser/ui/tabs/organizer",
    "//chrome/browser/ui/user_education",
    "//chrome/browser/ui/views:layout_provider",
    "//chrome/browser/ui/views/bookmarks",
    "//chrome/browser/ui/views/toolbar",
    "//components/favicon/core",
    "//components/feature_engagement/public",
    "//components/saved_tab_groups/public",
    "//skia",
    "//ui/accessibility",
    "//ui/compositor",
    "//ui/gfx/animation",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [
    "saved_tab_group_bar_browsertest.cc",
    "saved_tab_group_bar_component_browsertest.cc",
    "saved_tab_group_everything_menu_browsertest.cc",
    "saved_tab_group_iph_promo_test.cc",
    "saved_tab_group_tabs_menu_model_browsertest.cc",
  ]

  configs += [ "//build/config/compiler:no_exit_time_destructors" ]

  deps = [
    ":saved_tab_groups",
    "//chrome/browser/bookmarks",
    "//chrome/browser/bookmarks:test_support",
    "//chrome/browser/favicon",
    "//chrome/browser/tab_group_sync:factories",
    "//chrome/browser/ui",
    "//chrome/browser/ui/views/bookmarks",
    "//chrome/browser/ui/views/bookmarks:test_support",
    "//chrome/browser/ui/views/commerce",
    "//chrome/test:test_support",
    "//chrome/test:test_support_ui",
    "//chrome/test/user_education",
    "//components/commerce/core:shopping_service_test_support",
    "//components/saved_tab_groups/test_support",
    "//components/user_education/views",
    "//ui/events:test_support",
  ]
}

if (!is_chromeos_device) {
  source_set("interactive_ui_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

    sources = [
      "saved_tab_group_interactive_uitest.cc",
      "shared_tab_group_interactive_uitest.cc",
    ]

    configs += [ "//build/config/compiler:no_exit_time_destructors" ]

    deps = [
      ":saved_tab_groups",
      "//chrome/browser:chrome_content_browser_client",
      "//chrome/browser/apps/app_service",
      "//chrome/browser/apps/app_service/publishers",
      "//chrome/browser/bookmarks",
      "//chrome/browser/bookmarks:test_support",
      "//chrome/browser/collaboration/messaging",
      "//chrome/browser/data_sharing",
      "//chrome/browser/favicon",
      "//chrome/browser/gcm",
      "//chrome/browser/tab_group_sync:factories",
      "//chrome/browser/ui",
      "//chrome/browser/ui/actions",
      "//chrome/browser/ui/tabs:tab_menu",
      "//chrome/browser/ui/views/bookmarks",
      "//chrome/browser/ui/views/bookmarks:test_support",
      "//chrome/browser/ui/views/commerce",
      "//chrome/browser/ui/views/data_sharing",
      "//chrome/browser/ui/views/tabs:tab_group",
      "//chrome/browser/ui/views/tabs/groups",
      "//chrome/browser/ui/views/tabs/tab",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//chrome/test/user_education",
      "//components/commerce/core:shopping_service_test_support",
      "//components/favicon/content",
      "//ui/base:ozone_buildflags",
      "//ui/events:test_support",
    ]

    if (use_ozone) {
      deps += [ "//ui/ozone" ]
    }
  }
}