# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

assert(toolkit_views)

source_set("apps") {
  public = [ "chrome_native_app_window_views.h" ]

  public_deps = [
    "//chrome/browser/extensions",
    "//extensions/components/native_app_window",
    "//ui/base/mojom:ui_base_types",
    "//ui/views",
  ]

  if (use_aura) {
    public += [
      "app_window_easy_resize_window_targeter.h",
      "chrome_native_app_window_views_aura.h",
      "shaped_app_window_targeter.h",
    ]
    public_deps += [
      "//ui/aura",
      "//ui/wm",
    ]
  }

  if (is_chromeos) {
    public += [ "chrome_native_app_window_views_aura_ash.h" ]
    public_deps += [
      "//ash",
      "//chrome/browser/ui/exclusive_access",
      "//chrome/browser/ui/views/exclusive_access",
      "//components/services/app_service/public/cpp:app_types",
      "//ui/base",
      "//ui/display",
    ]
  }

  if (is_mac) {
    public += [
      "app_window_native_widget_mac.h",
      "chrome_native_app_window_views_mac.h",
    ]
  }

  if (is_win) {
    public += [
      "app_window_desktop_native_widget_aura_win.h",
      "app_window_desktop_window_tree_host_win.h",
      "app_window_frame_view_win.h",
      "chrome_native_app_window_views_win.h",
    ]
    public_deps += [
      "//ui/base/metadata",
      "//ui/gfx/geometry",
    ]
  }
}

source_set("impl") {
  sources = [ "chrome_native_app_window_views.cc" ]

  deps = [
    ":apps",
    "//chrome/app:command_ids",
    "//chrome/browser/app_mode",
    "//chrome/browser/devtools",
    "//chrome/browser/extensions",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui:accelerator_table",
    "//chrome/browser/ui/views/extensions:extensions_views_utils",
    "//components/favicon/content",
    "//components/zoom",
    "//extensions/browser",
    "//extensions/components/native_app_window",
    "//ui/base",
    "//ui/views",
    "//ui/views/controls/webview",
  ]

  if (use_aura) {
    sources += [
      "app_window_easy_resize_window_targeter.cc",
      "chrome_native_app_window_views_aura.cc",
      "shaped_app_window_targeter.cc",
    ]
    deps += [
      "//apps/ui/views",
      "//chrome/browser/web_applications",
      "//ui/aura",
      "//ui/wm",
    ]
  }

  if (is_chromeos) {
    sources += [
      "chrome_app_window_client_views_chromeos.cc",
      "chrome_native_app_window_views_aura_ash.cc",
    ]
    deps += [
      "//ash",
      "//ash/public/cpp",
      "//chrome/browser/apps:icon_standardizer",
      "//chrome/browser/apps/app_service",
      "//chrome/browser/ash/note_taking",
      "//chrome/browser/ui/apps",
      "//chrome/browser/ui/ash/multi_user",
      "//chrome/browser/ui/exclusive_access",
      "//chrome/browser/ui/views/exclusive_access",
      "//chromeos/components/mgs",
      "//chromeos/constants",
      "//chromeos/ui/base",
      "//chromeos/ui/frame",
      "//components/app_restore",
      "//components/services/app_service/public/cpp:app_types",
      "//ui/menus",
    ]
  }

  if (is_linux) {
    sources += [ "chrome_app_window_client_views_aura.cc" ]
    deps += [
      "//chrome/browser:shell_integration_linux",
      "//chrome/browser/ui/apps",
    ]
  }

  if (is_win) {
    sources += [
      "app_window_desktop_native_widget_aura_win.cc",
      "app_window_desktop_window_tree_host_win.cc",
      "app_window_frame_view_win.cc",
      "chrome_app_window_client_views_win.cc",
      "chrome_native_app_window_views_win.cc",
    ]
    deps += [
      "//chrome/browser:shell_integration",
      "//chrome/browser/ui/apps",
      "//chrome/browser/web_applications/extensions",
      "//chrome/common:constants",
      "//content/public/browser",
      "//extensions/common",
    ]
  }

  if (is_mac) {
    sources += [
      "app_window_native_widget_mac.mm",
      "chrome_app_window_client_views_mac.mm",
      "chrome_native_app_window_views_mac.mm",
    ]
    deps += [
      "//chrome/browser/apps/app_shim",
      "//chrome/browser/ui/apps",
      "//chrome/browser/ui/cocoa",
      "//components/remote_cocoa/app_shim",
      "//components/remote_cocoa/common:mojo",
    ]
  }
}

if (use_aura) {
  source_set("unit_tests") {
    testonly = true

    sources = [ "shaped_app_window_targeter_unittest.cc" ]

    configs += [ "//build/config/compiler:no_exit_time_destructors" ]

    deps = [
      ":apps",
      "//apps/ui/views",
      "//testing/gtest",
      "//ui/aura",
      "//ui/events",
      "//ui/views",
      "//ui/views:test_support",
      "//ui/views/controls/webview",
      "//ui/wm",
    ]
  }
}

if (is_chromeos) {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

    sources = [ "chrome_native_app_window_views_aura_ash_browsertest.cc" ]

    configs += [ "//build/config/compiler:no_exit_time_destructors" ]

    deps = [
      ":apps",
      "//ash/public/cpp",
      "//chrome/browser/apps/platform_apps:browser_test_support",
      "//chrome/browser/profiles:profile",
      "//chrome/browser/ui",
      "//chrome/test:test_support",
      "//chromeos/ash/components/login/login_state:test_support",
      "//chromeos/constants",
      "//chromeos/ui/base",
      "//chromeos/ui/frame",
      "//components/user_manager:test_support",
      "//content/test:test_support",
      "//extensions:test_support",
      "//extensions/browser",
      "//ui/aura",
      "//ui/base",
      "//ui/display",
      "//ui/views",
      "//ui/wm",
    ]
  }
}