# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//extensions/buildflags/buildflags.gni")

source_set("side_panel") {
  sources = [
    "side_panel_action_callback.cc",
    "side_panel_action_callback.h",
    "side_panel_content_proxy.cc",
    "side_panel_content_proxy.h",
    "side_panel_entry_id.cc",
    "side_panel_entry_id.h",
    "side_panel_entry_key.cc",
    "side_panel_entry_key.h",
    "side_panel_entry_observer.h",
    "side_panel_entry_scope.cc",
    "side_panel_entry_scope.h",
    "side_panel_enums.h",
    "side_panel_enums_utils.h",
    "side_panel_native_view.h",
    "side_panel_prefs.cc",
    "side_panel_prefs.h",
    "side_panel_ui.cc",
    "side_panel_ui.h",
  ]

  public_deps = [
    "//base",
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser/ui/tabs:tabs_public",
    "//components/tabs:public",
    "//content/public/browser",
    "//ui/base",
    "//ui/gfx/geometry",
  ]

  deps = [
    "//chrome/browser:primitives",
    "//chrome/browser/ui:ui_features",
    "//chrome/browser/ui/actions:actions_headers",
    "//components/pref_registry",
    "//url",
  ]

  if (enable_extensions) {
    deps += [ "//extensions/common:common_constants" ]
  }

  if (is_android) {
    deps += [ "//chrome/browser/ui/side_panel/android" ]
  }
}

source_set("side_panel_views_dependent") {
  sources = [
    "side_panel_entry.cc",
    "side_panel_entry.h",
    "side_panel_entry_waiter.cc",
    "side_panel_entry_waiter.h",
    "side_panel_metrics.cc",
    "side_panel_metrics.h",
    "side_panel_registry.cc",
    "side_panel_registry.h",
    "side_panel_ui_base.cc",
    "side_panel_ui_base.h",
    "side_panel_util.cc",
    "side_panel_util.h",
  ]
  deps = [
    ":side_panel",
    "//base",
    "//chrome/browser/tab_list",
    "//chrome/browser/ui/actions:actions_headers",
    "//chrome/browser/ui/browser_window",
    "//ui/base",
    "//ui/base/unowned_user_data",
  ]

  # No views dependency is allowed on Android.
  if (!is_android) {
    deps += [
      "//chrome/browser/ui/tabs:tab_strip",
      "//chrome/browser/ui/views/side_panel",
      "//ui/views",
    ]

    allow_circular_includes_from =
        [ "//chrome/browser/ui/views/side_panel:side_panel" ]
  }
}

source_set("side_panel_ui_provider") {
  sources = [
    "side_panel_ui_provider.cc",
    "side_panel_ui_provider.h",
  ]
  deps = [
    ":side_panel",
    ":side_panel_views_dependent",
    "//chrome/browser/ui/browser_window",
  ]
  if (is_android) {
    deps += [ "//chrome/browser/ui/side_panel/internal/android" ]
  } else {
    deps += [ "//chrome/browser/ui/views/side_panel" ]
  }
}

source_set("test_support") {
  testonly = true
  sources = [
    "mock_side_panel_ui.cc",
    "mock_side_panel_ui.h",
  ]

  deps = [
    ":side_panel",
    ":side_panel_views_dependent",
    "//testing/gmock",
    "//ui/base/unowned_user_data",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "side_panel_entry_key_unittest.cc" ]

  deps = [
    ":side_panel",
    "//chrome/browser/ui/actions:actions_headers",
    "//testing/gtest",
    "//ui/actions:actions_headers",
  ]

  if (!is_android) {
    sources += [ "side_panel_metrics_unittest.cc" ]
    deps += [
      ":side_panel_views_dependent",
      "//base/test:test_support",
    ]
  }
}