# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ozone.gni")
import("//build/config/ui.gni")

assert(is_win || is_mac || is_linux || is_chromeos)
assert(toolkit_views)

source_set("send_tab_to_self") {
  sources = [
    "send_tab_to_self_activation_tracker.h",
    "send_tab_to_self_bubble.h",
    "send_tab_to_self_context_menu_delegate.h",
    "send_tab_to_self_toolbar_icon_controller.h",
    "send_tab_to_self_util.h",
  ]

  public_deps = [
    "//base",
    "//chrome/browser/send_tab_to_self",
    "//components/send_tab_to_self",
    "//ui/menus",
  ]
  deps = [
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/views/toolbar",
  ]
}

source_set("impl") {
  sources = [
    "send_tab_to_self_activation_tracker.cc",
    "send_tab_to_self_context_menu_delegate.cc",
    "send_tab_to_self_toolbar_icon_controller.cc",
    "send_tab_to_self_util.cc",
  ]
  deps = [
    ":send_tab_to_self",
    "//chrome/browser:primitives",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/sync",
    "//chrome/browser/ui/actions:actions_headers",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/toasts",
    "//chrome/browser/ui/views/send_tab_to_self",
    "//chrome/browser/ui/views/toolbar",
    "//chrome/browser/user_education",
    "//components/send_tab_to_self",
    "//ui/strings:ui_strings_grit",
  ]
  public_deps = [ "//chrome/browser:browser_public_dependencies" ]
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [
      "send_tab_to_self_activation_tracker_browsertest.cc",
      "send_tab_to_self_toolbar_icon_controller_browsertest.cc",
    ]

    deps = [
      ":send_tab_to_self",
      "//chrome/browser/prefs:util",
      "//chrome/browser/sync",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/toasts",
      "//chrome/browser/ui/views/send_tab_to_self",
      "//chrome/browser/web_applications",
      "//chrome/browser/web_applications:web_applications_test_support",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//components/send_tab_to_self",
      "//components/send_tab_to_self:test_support",
      "//content/test:test_support",
      "//ui/base:ozone_buildflags",
    ]
    if (use_ozone) {
      deps += [ "//ui/ozone" ]
    }
  }
}

source_set("interactive_ui_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [ "send_tab_to_self_toolbar_icon_controller_interactive_uitest.cc" ]

  deps = [
    ":send_tab_to_self",
    "//base/test:test_support",
    "//chrome/browser/sync",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/toasts",
    "//chrome/browser/ui/views/send_tab_to_self",
    "//chrome/test:test_support",
    "//chrome/test:test_support_ui",
    "//components/send_tab_to_self",
    "//components/send_tab_to_self:test_support",
    "//content/test:test_support",
    "//ui/base:ozone_buildflags",
  ]
  if (use_ozone) {
    deps += [ "//ui/ozone" ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [
    "send_tab_to_self_activation_tracker_unittest.cc",
    "send_tab_to_self_context_menu_delegate_unittest.cc",
  ]
  deps = [
    ":send_tab_to_self",
    "//base",
    "//base/test:test_support",
    "//chrome/app:command_ids",
    "//chrome/browser/send_tab_to_self",
    "//chrome/browser/sync",
    "//chrome/test:test_support",
    "//components/send_tab_to_self",
    "//components/send_tab_to_self:test_support",
    "//content/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//url",
  ]
}