# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/ui.gni")

source_set("navigator") {
  public = [
    "browser_navigator_params.h",
    "browser_navigator_params_utils.h",
  ]

  if (!is_android) {
    public += [
      "browser_navigator.h",
      "browser_navigator_tab_modal.h",
    ]
  }

  public_deps = [
    "//base",
    "//build:android_buildflags",
    "//chrome/browser/ui/tabs:tab_enums",
    "//components/captive_portal/core",
    "//components/tab_groups",
    "//components/webapps/browser",
    "//content/public/browser",
    "//content/public/common",
    "//services/network/public/cpp",
    "//third_party/blink/public/common",
    "//third_party/blink/public/common:headers",
    "//third_party/blink/public/common/tokens:tokens_headers",
    "//ui/base",
    "//ui/base:types",
    "//ui/gfx/geometry",
    "//url",
  ]
}

source_set("impl") {
  sources = [
    "browser_navigator_params.cc",
    "browser_navigator_params_utils.cc",
  ]

  deps = [
    ":navigator",
    "//base",
    "//chrome/browser:browser_about_handler",
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser:primitives",
    "//chrome/browser/picture_in_picture",
    "//chrome/browser/prefs",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/renderer_host",
    "//chrome/browser/search_engines",
    "//chrome/browser/tab_contents",
    "//chrome/browser/tab_list",
    "//chrome/browser/ui",
    "//chrome/browser/ui:incognito_allowed_url",
    "//chrome/browser/ui/browser_window:create_browser_window",
    "//chrome/common:chrome_features",
    "//components/captive_portal/content",
    "//components/captive_portal/core:buildflags",
    "//components/no_state_prefetch/browser",
    "//components/omnibox/browser",
    "//components/search_engines",
    "//components/tabs:public",
    "//content/public/browser",
    "//ui/base",
    "//url",
  ]

  if (is_chromeos) {
    deps += [
      "//chrome/browser/ash/boca/on_task",
      "//chrome/browser/ui/ash/system_web_apps",
    ]
  }

  if (!is_android) {
    sources += [
      "browser_navigator.cc",
      "browser_navigator_tab_modal.cc",
    ]

    deps += [
      "//chrome/browser/apps/app_service",
      "//chrome/browser/apps/link_capturing",
      "//chrome/browser/ui:browser_init_state",
      "//chrome/browser/ui:status_bubble",
      "//chrome/browser/ui/browser_ui_controller",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/location_bar",
      "//chrome/browser/ui/tabs:tab_strip",
      "//chrome/browser/ui/web_applications",
      "//chrome/browser/ui/web_applications:launch_utils",
      "//chrome/browser/ui/window_feature_controller",
    ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [ "browser_navigator_params_utils_unittest.cc" ]

  deps = [
    ":impl",
    ":navigator",
    "//base",
    "//chrome/browser/tab_list:test_support",
    "//chrome/browser/ui:test_support",
    "//chrome/test:test_support",
    "//components/tabs:test_support",
    "//content/public/browser",
    "//content/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//ui/base/unowned_user_data",
  ]
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [
      "browser_navigator_browsertest.cc",
      "browser_navigator_browsertest.h",
    ]

    if (is_chromeos) {
      sources += [ "browser_navigator_browsertest_chromeos.cc" ]
    }

    deps = [
      ":impl",
      "//base",
      "//chrome/app:command_ids",
      "//chrome/browser/file_system_access",
      "//chrome/browser/picture_in_picture",
      "//chrome/browser/prefs",
      "//chrome/browser/renderer_host",
      "//chrome/browser/ui:browser_init_state",
      "//chrome/browser/ui:chrome_pages",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/browser_window:create_browser_window",
      "//chrome/browser/ui/page_info",
      "//chrome/browser/ui/search:test_support_ui",
      "//chrome/test:test_support",
      "//components/captive_portal/content",
      "//content/test:test_support",
      "//testing/gtest",
    ]

    if (is_chromeos) {
      deps += [
        "//chrome/browser/ash/boca/on_task",
        "//chrome/browser/ui/ash/multi_user",
        "//chrome/browser/ui/ash/session",
        "//components/account_id:test_support",
      ]
    }

    if (use_ozone) {
      deps += [ "//ui/ozone" ]
    }
  }
}