# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

# Android targets need to be guarded by is_android because:
# (1) Android GNI files may assert is_android, and
# (2) The rest of this file can be included in non-Android builds.
if (is_android) {
  import("//build/config/android/rules.gni")
  import("//third_party/jni_zero/jni_zero.gni")

  # Supports Java unit tests.
  android_library("junit_test_support") {
    testonly = true
    sources = [ "android/java/src/org/chromium/chrome/browser/ui/browser_window/ChromeAndroidTaskUnitTestSupport.java" ]
    deps = [
      "//base:base_java",
      "//base:flagged_apis_java",
      "//build/android:build_java",
      "//chrome/browser/android/customtabs:java",
      "//chrome/browser/android/lifecycle:java",
      "//chrome/browser/profiles/android:java",
      "//chrome/browser/tabmodel:java",
      "//chrome/browser/ui/android/desktop_windowing:java",
      "//chrome/browser/ui/android/multiwindow:java",
      "//chrome/browser/ui/browser_window/internal:java",
      "//chrome/browser/ui/browser_window/public/android:java",
      "//chrome/browser/util:java",
      "//components/browser_ui/desktop_windowing/android:java",
      "//content/public/android:content_full_java",
      "//third_party/androidx:androidx_annotation_annotation_java",
      "//third_party/androidx:androidx_core_core_java",
      "//third_party/mockito:mockito_java",
      "//ui/android:ui_no_recycler_view_java",
      "//ui/base/mojom:ui_base_types_java",
    ]
  }

  source_set("android_browser_test_support") {
    testonly = true
    sources = [
      "android/browser_window_android_browsertest_base.cc",
      "android/browser_window_android_browsertest_base.h",
    ]
    deps = [
      "//chrome/browser/flags:flags_android",
      "//chrome/test:test_support_ui_android",
    ]
  }

  # Supports native unit tests.
  android_library("native_unit_test_support_java") {
    testonly = true
    sources = [
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBaseWindowNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBrowserWindowEnumeratorNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBrowserWindowNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/BrowserWindowInterfaceIteratorAndroidNativeUnitTestSupport.java",
    ]
    deps = [
      ":junit_test_support",
      "//base:tasks_java",
      "//build/android:build_java",
      "//chrome/browser/android/lifecycle:java",
      "//chrome/browser/profiles/android:java",
      "//chrome/browser/tabmodel:java",
      "//chrome/browser/ui/android/multiwindow:java",
      "//chrome/browser/ui/android/tab_model:test_support",
      "//chrome/browser/ui/browser_window/internal:java",
      "//chrome/browser/ui/browser_window/public/android:java",
      "//third_party/jni_zero:jni_zero_java",
      "//third_party/mockito:mockito_java",
      "//ui/android:ui_no_recycler_view_java",
    ]
    srcjar_deps = [ ":native_unit_test_support_jni" ]
  }

  # JNI for native unit tests.
  generate_jni("native_unit_test_support_jni") {
    testonly = true
    sources = [
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBaseWindowNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBrowserWindowEnumeratorNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/AndroidBrowserWindowNativeUnitTestSupport.java",
      "android/java/src/org/chromium/chrome/browser/ui/browser_window/BrowserWindowInterfaceIteratorAndroidNativeUnitTestSupport.java",
    ]
  }
}

static_library("test_support") {
  testonly = true
  sources = [
    "browser_event_waiter.cc",
    "browser_event_waiter.h",
    "fake_global_browser_collection.h",
  ]
  deps = [
    "//base",
    "//chrome/browser/ui/browser_window",
  ]
}