# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("trusted_vault") {
  public = [
    "trusted_vault_encryption_keys_tab_helper.h",
    "trusted_vault_service_factory.h",
  ]
  public_deps = [
    "//base",
    "//chrome/browser/profiles:profile",
    "//chrome/common:mojo_bindings",
    "//components/trusted_vault",
    "//content/public/browser",
  ]
}

source_set("impl") {
  sources = [
    "trusted_vault_encryption_keys_tab_helper.cc",
    "trusted_vault_service_factory.cc",
  ]
  public_deps = [ ":trusted_vault" ]
  deps = [
    "//chrome/browser/signin",
    "//chrome/browser/signin:google_accounts_private_api",
    "//chrome/browser/webauthn",
    "//chrome/common:version_header",
    "//components/signin/public/identity_manager",
    "//google_apis",
  ]

  if (is_android) {
    deps += [ "//components/trusted_vault/android" ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = [ "trusted_vault_encryption_keys_tab_helper_unittest.cc" ]
  deps = [
    ":trusted_vault",
    "//base",
    "//base/test:test_support",
    "//chrome/common:mojo_bindings",
    "//chrome/test:test_support",
    "//components/site_isolation",
  ]
}

if (is_android) {
  source_set("android_browsertests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [ "trusted_vault_encryption_keys_tab_helper_browsertest.cc" ]
    deps = [
      ":trusted_vault",
      "//base",
      "//base/test:test_support",
      "//chrome/browser/preloading:test_support",
      "//chrome/common:constants",
      "//chrome/test:test_support",
      "//components/site_isolation",
    ]
  }
} else {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [ "trusted_vault_encryption_keys_tab_helper_browsertest.cc" ]
    deps = [
      ":trusted_vault",
      "//base",
      "//base/test:test_support",
      "//chrome/browser/preloading:test_support",
      "//chrome/browser/signin",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/webauthn",
      "//chrome/browser/webauthn:test_support",
      "//chrome/common:constants",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//components/metrics:content",
      "//components/signin/public/identity_manager",
      "//components/signin/public/identity_manager:test_support",
      "//components/site_isolation",
      "//content/test:test_support",
      "//google_apis",
    ]
  }
}