# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//components/guest_view/buildflags/buildflags.gni")

source_set("storage_access_api") {
  sources = [
    "site_pair_cache.cc",
    "site_pair_cache.h",
    "storage_access_api_service.h",
    "storage_access_api_service_factory.cc",
    "storage_access_api_service_factory.h",
    "storage_access_api_service_impl.cc",
    "storage_access_api_service_impl.h",
    "storage_access_api_tab_helper.cc",
    "storage_access_api_tab_helper.h",
    "storage_access_grant_permission_context.cc",
    "storage_access_grant_permission_context.h",
  ]

  public_deps = [
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser/profiles:profile",
    "//components/permissions",
  ]

  deps = [
    "//chrome/browser:bad_message",
    "//chrome/browser/content_settings:content_settings_factory",
    "//chrome/browser/first_party_sets",
    "//chrome/browser/webid",
    "//chrome/common",
    "//components/content_settings/browser",
    "//components/content_settings/core/browser",
    "//components/content_settings/core/browser:cookie_settings",
    "//components/guest_view/buildflags",
    "//components/metrics/dwa:dwa_builders",
    "//components/metrics/private_metrics",
    "//content/public/browser",
    "//services/network/public/mojom",
  ]

  if (enable_guest_view) {
    deps += [ "//components/guest_view/browser" ]
  }
}

source_set("unit_tests") {
  testonly = true

  # storage_access_grant_permission_context_unittest.cc has file-scope
  # non-trivial statics, which -Wexit-time-destructors rejects.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]

  sources = [
    "site_pair_cache_unittest.cc",
    "storage_access_api_service_factory_unittest.cc",
    "storage_access_api_service_impl_unittest.cc",
    "storage_access_api_tab_helper_unittest.cc",
    "storage_access_grant_permission_context_unittest.cc",
  ]

  deps = [
    ":storage_access_api",
    "//base",
    "//base/test:test_support",
    "//chrome/browser/content_settings",
    "//chrome/browser/content_settings:content_settings_factory",
    "//chrome/browser/webid",
    "//chrome/test:test_support",
    "//components/content_settings/core/browser",
    "//components/content_settings/core/common",
    "//components/metrics/private_metrics:dwa_recorder",
    "//components/permissions",
    "//components/permissions:test_support",
    "//components/privacy_sandbox:privacy_sandbox_prefs",
    "//content/test:test_support",
    "//testing/gmock",
    "//testing/gtest",
  ]
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true

    # api_browsertest.cc has file-scope non-trivial statics, which
    # -Wexit-time-destructors rejects.
    configs += [ "//build/config/compiler:no_exit_time_destructors" ]

    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

    sources = [ "api_browsertest.cc" ]

    deps = [
      ":storage_access_api",
      "//base",
      "//chrome/browser/net:storage_test_utils",
      "//chrome/browser/policy:test_support",
      "//chrome/browser/ui",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/webid",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//content/test:test_support",
      "//testing/gtest",
    ]
  }
}