# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/android/rules.gni")
import("//third_party/jni_zero/jni_zero.gni")

generate_jni("jni_headers") {
  sources = [
    "java/src/org/chromium/chrome/browser/signin/services/AccountPreviewDataService.java",
    "java/src/org/chromium/chrome/browser/signin/services/AccountPreviewPreference.java",
    "java/src/org/chromium/chrome/browser/signin/services/IdentityServicesProvider.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninManagerImpl.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninMetricsUtils.java",
    "java/src/org/chromium/chrome/browser/signin/services/UnifiedConsentServiceBridge.java",
    "java/src/org/chromium/chrome/browser/signin/services/WebSigninBridge.java",
  ]
}

android_library("java") {
  sources = [
    "java/src/org/chromium/chrome/browser/signin/services/AccountPreviewDataService.java",
    "java/src/org/chromium/chrome/browser/signin/services/AccountPreviewPreference.java",
    "java/src/org/chromium/chrome/browser/signin/services/BadgeConfig.java",
    "java/src/org/chromium/chrome/browser/signin/services/DisplayableProfileData.java",
    "java/src/org/chromium/chrome/browser/signin/services/IdentityServicesProvider.java",
    "java/src/org/chromium/chrome/browser/signin/services/ProfileDataCache.java",
    "java/src/org/chromium/chrome/browser/signin/services/ProfileDataUtils.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninChecker.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninFlowTimestampsLogger.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninManager.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninManagerImpl.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninMetricsUtils.java",
    "java/src/org/chromium/chrome/browser/signin/services/SigninPreferencesManager.java",
    "java/src/org/chromium/chrome/browser/signin/services/SubscriptionTierBrandingDelegate.java",
    "java/src/org/chromium/chrome/browser/signin/services/UnifiedConsentServiceBridge.java",
    "java/src/org/chromium/chrome/browser/signin/services/WebSigninBridge.java",
  ]
  deps = [
    ":java_resources",
    "//base:base_java",
    "//base:service_loader_java",
    "//base/version_info/android:version_constants_java",
    "//build/android:build_java",
    "//chrome/browser/first_run/android:java",
    "//chrome/browser/flags:java",
    "//chrome/browser/preferences:java",
    "//chrome/browser/profiles/android:java",
    "//chrome/browser/subscription_eligibility:java",
    "//chrome/browser/sync/android:java",
    "//components/browser_ui/util/android:java",
    "//components/externalauth/android:java",
    "//components/metrics:metrics_java",
    "//components/prefs/android:java",
    "//components/signin/core/browser:signin_enums_java",
    "//components/signin/public/android:java",
    "//components/sync/android:sync_java",
    "//components/variations/android:variations_java",
    "//google_apis/gaia/android:java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_appcompat_appcompat_resources_java",
    "//third_party/androidx:androidx_core_core_java",
    "//third_party/jni_zero:jni_zero_java",
  ]
  srcjar_deps = [
    ":jni_headers",
    "//components/signin/public/browser:java_enums",
  ]
  resources_package = "org.chromium.chrome.browser.signin.services"
}

android_resources("java_resources") {
  sources = [
    "java/res/drawable/ic_error_badge_16dp.xml",
    "java/res/values/dimens.xml",
  ]
  deps = [
    "//chrome/browser/ui/android/strings:ui_strings_grd",
    "//components/signin/public/android:java_resources",
  ]
}

android_library("unit_device_javatests") {
  testonly = true
  resources_package = "org.chromium.chrome.browser.signin.services"
  sources = [
    "java/src/org/chromium/chrome/browser/signin/services/ProfileDataCacheRenderTest.java",
    "java/src/org/chromium/chrome/browser/signin/services/ProfileDataCacheWithBadgeRenderTest.java",
  ]
  deps = [
    ":java",
    "//base:base_java_test_support",
    "//base:features_java",
    "//chrome/android:chrome_app_java_resources",
    "//chrome/android:chrome_java",
    "//chrome/browser/bookmarks/android:java",
    "//chrome/browser/flags:java",
    "//chrome/browser/profiles/android:java",
    "//chrome/browser/subscription_eligibility:java",
    "//chrome/test/android:chrome_java_integration_test_support",
    "//components/browser_ui/util/android:java",
    "//components/signin/public/android:java",
    "//components/signin/public/android:signin_java_test_support",
    "//content/public/test/android:content_java_test_support",
    "//google_apis/gaia/android:java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/android:ui_java_test_support",
    "//ui/android:ui_no_recycler_view_java",
  ]
}

robolectric_library("junit") {
  resources_package = "org.chromium.chrome.browser.signin.services"
  sources = [
    "java/src/org/chromium/chrome/browser/signin/services/SigninFlowTimestampsLoggerUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/AccountPreviewDataServiceUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/BadgeConfigBuilderUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/DisplayableProfileDataUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/ProfileDataCacheUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/ProfileDataUtilsUnitTest.java",
    "junit/src/org/chromium/chrome/browser/signin/services/WebSigninBridgeTest.java",
  ]
  deps = [
    ":java",
    ":java_resources",
    "//base:base_java_test_support",
    "//base:base_java_test_support_uncommon",
    "//base:base_junit_test_support",
    "//base:callback_java",
    "//base:features_java",
    "//base:promise_java",
    "//chrome/android:chrome_app_java_resources",
    "//chrome/android:chrome_java",
    "//chrome/browser/flags:java",
    "//chrome/browser/profiles/android:java",
    "//chrome/browser/subscription_eligibility:java",
    "//chrome/browser/tab:java",
    "//chrome/browser/ui/android/signin:java",
    "//chrome/test/android:chrome_java_unit_test_support",
    "//components/browser_ui/util/android:java",
    "//components/signin/public/android:java",
    "//components/signin/public/android:signin_java_test_support",
    "//components/sync/android:sync_java",
    "//google_apis/gaia/android:java",
    "//third_party/androidx:androidx_test_core_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/android:ui_java",
    "//url:gurl_java",
  ]
}

android_library("javatests") {
  testonly = true
  resources_package = "org.chromium.chrome.browser.signin.services"
  sources = [ "java/src/org/chromium/chrome/browser/signin/services/SigninManagerImplTest.java" ]
  deps = [
    ":java",
    "//base:base_java_test_support",
    "//base:base_shared_preferences_java",
    "//chrome/android:chrome_app_java_resources",
    "//chrome/android:chrome_java",
    "//chrome/browser/bookmarks/android:java",
    "//chrome/browser/flags:java",
    "//chrome/browser/preferences:java",
    "//chrome/browser/profiles/android:java",
    "//chrome/test/android:chrome_java_integration_test_support",
    "//chrome/test/android:chrome_java_transit",
    "//components/bookmarks/common/android:bookmarks_java",
    "//components/embedder_support/android:util_java",
    "//components/externalauth/android:java",
    "//components/prefs/android:java",
    "//components/signin/public/android:java",
    "//components/signin/public/android:signin_java_test_support",
    "//components/user_prefs/android:java",
    "//content/public/android:content_full_java",
    "//content/public/test/android:content_java_test_support",
    "//google_apis/gaia/android:java",
    "//third_party/androidx:androidx_annotation_annotation_java",
    "//third_party/androidx:androidx_test_runner_java",
    "//third_party/jni_zero:jni_zero_java",
    "//third_party/junit",
    "//third_party/mockito:mockito_java",
    "//ui/android:ui_java_test_support",
    "//ui/android:ui_no_recycler_view_java",
    "//url:url_java",
  ]
}