# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("ntp_tiles") {
  sources = [
    "chrome_custom_links_manager_factory.h",
    "chrome_enterprise_shortcuts_manager_factory.h",
    "chrome_most_visited_sites_factory.h",
    "chrome_popular_sites_factory.h",
  ]
}

source_set("impl") {
  sources = [
    "chrome_custom_links_manager_factory.cc",
    "chrome_enterprise_shortcuts_manager_factory.cc",
    "chrome_most_visited_sites_factory.cc",
    "chrome_popular_sites_factory.cc",
  ]
  public_deps = [ ":ntp_tiles" ]
  deps = [
    "//base",
    "//chrome/browser:browser_process",
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser/favicon",
    "//chrome/browser/history",
    "//chrome/browser/image_fetcher",
    "//chrome/browser/search_engines",
    "//chrome/browser/signin",
    "//chrome/browser/supervised_user",
    "//components/history/core/browser",
    "//components/image_fetcher/core",
    "//components/ntp_tiles",
    "//content/public/browser",
    "//services/data_decoder/public/cpp",
  ]

  if (is_android) {
    deps += [ "//chrome/browser/flags:flags_android" ]
  }
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [ "ntp_tiles_browsertest.cc" ]
    deps = [
      ":impl",
      ":ntp_tiles",
      "//chrome/browser",
      "//chrome/test:test_support",
      "//chrome/test/supervised_user:test_support",
      "//content/public/browser",
      "//testing/gmock",
      "//testing/gtest",
    ]
  }
}