# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("multistep_filter") {
  sources = []
  public_deps = []
  deps = []

  if (!is_android) {
    public_deps += [
      "//chrome/browser/multistep_filter/core",
      "//chrome/browser/ui/tabs",
      "//ui/base/unowned_user_data",
    ]
    sources += [
      "chrome_filter_navigation_observer.cc",
      "chrome_filter_navigation_observer.h",
      "multistep_filter_ui_delegate_impl.cc",
      "multistep_filter_ui_delegate_impl.h",
    ]
    deps += [
      "//base",
      "//chrome/browser/multistep_filter/ui",
      "//chrome/browser/profiles:profile",
      "//components/multistep_filter/content",
      "//components/multistep_filter/core",
      "//components/multistep_filter/core:features",
      "//components/tabs:public",
      "//content/public/browser",
      "//url",
    ]
  }
}

source_set("test_support") {
  testonly = true
  sources = []
  deps = []
  if (!is_android) {
    sources += [ "chrome_filter_navigation_observer_test_api.h" ]
    deps += [
      ":multistep_filter",
      "//base",
    ]
  }
}

source_set("unit_tests") {
  testonly = true
  sources = []
  deps = []

  if (!is_android) {
    sources += [
      "chrome_filter_navigation_observer_unittest.cc",
      "multistep_filter_ui_delegate_impl_unittest.cc",
    ]
    deps += [
      ":multistep_filter",
      ":test_support",
      "//base/test:test_support",
      "//chrome/browser/multistep_filter/core:unit_tests",
      "//chrome/browser/multistep_filter/ui",
      "//chrome/browser/multistep_filter/ui:unit_tests",
      "//chrome/browser/ui/tabs:tab_model",
      "//chrome/test:test_support",
      "//components/multistep_filter/content:test_support",
      "//components/multistep_filter/core",
      "//components/multistep_filter/core:features",
      "//components/multistep_filter/core:util",
      "//components/multistep_filter/core/annotation_index:test_support",
      "//components/multistep_filter/core/prefs",
      "//components/tabs:test_support",
      "//components/unified_consent",
      "//content/test:test_support",
      "//testing/gmock",
      "//testing/gtest",
      "//url",
    ]
  }
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = []
  deps = []

  if (!is_android) {
    sources += [ "multistep_filter_browsertest.cc" ]
    deps += [
      ":multistep_filter",
      ":test_support",
      "//base",
      "//base/test:test_support",
      "//chrome/browser/multistep_filter/ui",
      "//chrome/browser/multistep_filter/ui:test_support",
      "//chrome/browser/signin",
      "//chrome/browser/sync",
      "//chrome/browser/ui",
      "//chrome/browser/ui:browser_actions",
      "//chrome/browser/ui/browser_window",
      "//chrome/browser/ui/toasts",
      "//chrome/common",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//components/history/core/browser",
      "//components/multistep_filter/content:test_support",
      "//components/multistep_filter/core:features",
      "//components/multistep_filter/core:switches",
      "//components/multistep_filter/core:test_support",
      "//components/prefs",
      "//components/signin/public/identity_manager:test_support",
      "//components/sync/service",
      "//components/unified_consent",
      "//content/test:test_support",
      "//net:test_support",
      "//testing/gtest",
      "//url",
    ]
  }
}