# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_win || is_mac || is_linux || is_chromeos || is_android)

source_set("lookalikes") {
  sources = [
    "lookalike_url_blocking_page.h",
    "lookalike_url_controller_client.h",
    "lookalike_url_navigation_throttle.h",
    "lookalike_url_service.h",
    "lookalike_url_service_factory.h",
    "lookalike_url_tab_storage.h",
    "safety_tip_ui.h",
    "safety_tip_ui_helper.h",
    "safety_tip_web_contents_observer.h",
  ]
  public_deps = [
    "//base",
    "//chrome/browser/profiles:profile",
    "//components/content_settings/core/browser",
    "//components/keyed_service/core",
    "//components/lookalikes/core",
    "//components/security_interstitials/content:security_interstitial_page",
    "//components/security_state/core",
    "//components/url_formatter",
    "//content/public/browser",
    "//content/public/common",
    "//services/metrics/public/cpp:metrics_cpp",
    "//url",
  ]
  if (is_android) {
    sources += [ "safety_tip_message_delegate_android.h" ]
    public_deps += [ "//components/messages/android" ]
  } else {
    public_deps += [ "//ui/views" ]
  }
}

source_set("impl") {
  sources = [
    "lookalike_url_blocking_page.cc",
    "lookalike_url_controller_client.cc",
    "lookalike_url_navigation_throttle.cc",
    "lookalike_url_service.cc",
    "lookalike_url_service_factory.cc",
    "lookalike_url_tab_storage.cc",
    "safety_tip_ui_helper.cc",
    "safety_tip_web_contents_observer.cc",
  ]
  public_deps = [ "//chrome/browser:browser_public_dependencies" ]
  deps = [
    ":lookalikes",
    "//chrome/browser:browser_process",
    "//chrome/browser/content_settings:content_settings_factory",
    "//chrome/browser/preloading/prefetch/no_state_prefetch",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/safe_browsing",
    "//components/lookalikes/core",
    "//components/lookalikes/core:safety_tips",
    "//components/no_state_prefetch/browser",
    "//components/resources",
    "//components/security_interstitials/core",
    "//components/security_state/content",
    "//components/site_engagement/content",
    "//components/strings:components_strings",
    "//components/url_formatter/spoof_checks/top_domains:common",
    "//components/url_formatter/spoof_checks/top_domains:top_bucket_domains_header",
    "//net",
    "//services/metrics/public/cpp:ukm_builders",
    "//ui/base",
  ]
  if (is_android) {
    sources += [ "safety_tip_message_delegate_android.cc" ]
    deps += [
      "//chrome/browser/android:tabs_public",
      "//chrome/browser/ui/android/tab_model",
      "//components/messages/android",
    ]
  }
}

source_set("test_support") {
  testonly = true
  sources = [
    "lookalike_test_helper.cc",
    "lookalike_test_helper.h",
  ]
  deps = [
    ":lookalikes",
    "//base",
    "//components/lookalikes/core",
    "//components/lookalikes/core:safety_tips",
    "//components/ukm:test_support",
    "//components/url_formatter",
    "//components/url_formatter/spoof_checks/top_domains:generate_top_domains_test_trie",
    "//components/url_formatter/spoof_checks/top_domains:test_top_bucket_domains",
    "//components/url_formatter/spoof_checks/top_domains:test_top_bucket_domains_header",
    "//services/metrics/public/cpp:ukm_builders",
    "//testing/gtest",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = []
  deps = [
    ":impl",
    ":lookalikes",
    "//chrome/test:test_support",
    "//components/lookalikes/core:safety_tips",
    "//content/test:test_support",
    "//testing/gtest",
  ]
  if (is_android) {
    sources += [ "safety_tip_message_delegate_android_unittest.cc" ]
    deps += [
      "//base/test:test_support",
      "//components/messages/android",
      "//components/messages/android:test_support",
      "//components/strings:components_strings",
      "//content/public/browser",
      "//ui/base",
    ]
  } else {
    sources += [ "lookalike_url_navigation_throttle_unittest.cc" ]
    deps += [ "//components/url_formatter" ]
  }
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true
    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
    sources = [ "lookalike_url_navigation_throttle_browsertest.cc" ]
    deps = [
      ":impl",
      ":lookalikes",
      ":test_support",
      "//chrome/browser/ui/browser_window",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//components/lookalikes/core",
      "//components/lookalikes/core:safety_tips",
      "//components/omnibox/browser",
      "//components/url_formatter/spoof_checks/top_domains:test_top_bucket_domains_header",
      "//services/metrics/public/cpp:metrics_cpp",
      "//services/metrics/public/cpp:ukm_builders",
    ]
  }
}