# Copyright 2026 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//components/optimization_guide/features.gni")

source_set("history_embeddings") {
  sources = [
    "chrome_history_embeddings_service.h",
    "history_embeddings_service_factory.h",
    "history_embeddings_tab_helper.h",
    "history_embeddings_utils.h",
  ]

  public_deps = [
    "//base",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/resource_coordinator",
    "//components/history/core/browser",
    "//components/history_embeddings/content",
    "//content/public/browser",
  ]
}

source_set("impl") {
  sources = [
    "chrome_history_embeddings_service.cc",
    "history_embeddings_service_factory.cc",
    "history_embeddings_tab_helper.cc",
    "history_embeddings_utils.cc",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]

  deps = [
    ":history_embeddings",
    "//chrome/app:generated_resources",
    "//chrome/browser:browser_process",
    "//chrome/browser/app_mode",
    "//chrome/browser/history",
    "//chrome/browser/optimization_guide",
    "//chrome/browser/page_content_annotations",
    "//chrome/browser/passage_embeddings",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/profiles:profile_util",
    "//chrome/browser/resource_coordinator",
    "//chrome/common:constants",
    "//components/history/core/browser",
    "//components/history_embeddings/content",
    "//components/history_embeddings/core",
    "//components/keyed_service/core",
    "//components/optimization_guide/core",
    "//components/optimization_guide/proto:optimization_guide_proto",
    "//components/passage_embeddings/core",
    "//components/prefs",
    "//components/strings",
    "//components/variations/service",
    "//content/public/browser",
    "//mojo/public/cpp/bindings",
    "//services/service_manager/public/cpp",
    "//ui/base",
    "//url",
  ]

  if (is_chromeos) {
    deps += [
      "//chrome/browser/ash/profiles",
      "//chromeos/constants",
    ]
  }
}

if (!is_android) {
  source_set("browser_tests") {
    testonly = true

    defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

    sources = [ "history_embeddings_service_browsertest.cc" ]

    deps = [
      ":history_embeddings",
      "//base",
      "//base/test:test_support",
      "//chrome/browser/optimization_guide:test_support",
      "//chrome/browser/page_content_annotations",
      "//chrome/browser/passage_embeddings",
      "//chrome/browser/profiles:profile",
      "//chrome/browser/ui",
      "//chrome/browser/ui/tabs:tabs_public",
      "//chrome/test:test_support",
      "//chrome/test:test_support_ui",
      "//components/history_embeddings/content",
      "//components/history_embeddings/core",
      "//components/keyed_service/content",
      "//components/optimization_guide/core:test_support",
      "//components/page_content_annotations/core",
      "//components/page_content_annotations/core:test_support",
      "//components/passage_embeddings/core:test_support",
      "//content/public/browser",
      "//content/test:test_support",
      "//testing/gmock",
      "//testing/gtest",
    ]
  }
}