# Copyright 2025 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

source_set("common") {
  sources = [
    "future_browser_features.h",
    "glic_navigation.cc",
    "glic_navigation.h",
    "glic_tab_observer.cc",
    "glic_tab_observer.h",
  ]

  deps = [
    "//base",
    "//chrome/browser:browser_public_dependencies",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/navigator",
    "//components/tabs:public",
  ]

  if (is_android) {
    sources += [
      "glic_tab_observer_android.cc",
      "glic_tab_observer_android.h",
    ]
    deps += [
      "//chrome/browser/android:tabs_public",
      "//chrome/browser/tab",
      "//chrome/browser/ui/android/tab_model",
      "//chrome/browser/ui/tabs:tabs_public",
      "//content/public/browser",
    ]
  } else {
    sources += [
      "glic_tab_observer_impl.cc",
      "glic_tab_observer_impl.h",
    ]
    deps += [
      "//chrome/browser/ui/tabs",
      "//chrome/browser/ui/tabs:tab_strip",
      "//content/public/browser",
      "//ui/base",
    ]
  }
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]
  sources = [ "glic_tab_observer_browsertest.cc" ]
  deps = [
    ":common",
    "//base",
    "//chrome/browser",
    "//chrome/browser/glic",
    "//chrome/browser/glic/test_support",
    "//chrome/browser/tab_list",
    "//chrome/browser/ui/browser_window",
    "//chrome/browser/ui/browser_window:create_browser_window",
    "//chrome/test:test_support",
    "//components/tabs:public",
    "//content/test:test_support",
  ]
  if (!is_android) {
    deps += [
      "//chrome/browser/ui",
      "//chrome/browser/ui/tabs:tab_strip",
    ]
  }
}