# Copyright 2020 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(!is_android && !is_fuchsia)

source_set("constants") {
  sources = [
    "constants.cc",
    "constants.h",
  ]
}

static_library("error_reporting") {
  sources = [
    "chrome_js_error_report_processor.cc",
    "chrome_js_error_report_processor.h",
  ]
  deps = [
    "//base",
    "//build:branding_buildflags",
    "//chrome/common:constants",
    "//components/crash/content/browser/error_reporting",
    "//components/crash/core/app",
    "//components/feedback/redaction_tool",
    "//components/startup_metric_utils",
    "//components/upload_list",
    "//components/variations",
    "//content/public/browser",
    "//net",
    "//services/network:network_service",
    "//services/network/public/cpp",
  ]
  if (is_chromeos) {
    sources += [ "chrome_js_error_report_processor_chromeos.cc" ]
    deps += [ ":constants" ]
  } else {
    sources += [ "chrome_js_error_report_processor_nonchromeos.cc" ]
  }
}

source_set("test_support") {
  testonly = true
  sources = [
    "mock_chrome_js_error_report_processor.cc",
    "mock_chrome_js_error_report_processor.h",
  ]
  deps = [
    ":error_reporting",
    "//base",
    "//base/test:test_support",
    "//chrome/common:constants",
    "//components/crash/content/browser/error_reporting",
    "//components/variations",
  ]
  public_deps = [
    "//components/crash/content/browser/error_reporting:mock_crash_endpoint",
  ]
  if (is_chromeos) {
    data_deps = [ ":mock_chromeos_crash_reporter" ]
  }
}

source_set("unit_test") {
  testonly = true
  sources = [ "chrome_js_error_report_processor_unittest.cc" ]
  deps = [
    ":error_reporting",
    ":test_support",
    "//base",
    "//chrome/browser/crash_upload_list",
    "//chrome/test:test_support",
    "//components/crash/content/browser/error_reporting",
    "//components/crash/content/browser/error_reporting:mock_crash_endpoint",
    "//components/crash/core/app",
    "//components/upload_list",
    "//content/test:test_support",
    "//net:test_support",
    "//testing/gtest",
  ]
}

if (is_chromeos) {
  executable("mock_chromeos_crash_reporter") {
    testonly = true
    sources = [ "mock_chromeos_crash_reporter.cc" ]

    deps = [
      ":constants",
      "//base",
      "//net",
      "//third_party/crashpad/crashpad/third_party/cpp-httplib",
    ]
  }
}

source_set("browser_tests") {
  testonly = true

  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [
    "crash_client_upload_info_browsertest.cc",
    "webui_js_error_reporting_browsertest.cc",
  ]

  deps = [
    ":test_support",
    "//base",
    "//chrome/browser:browser_process",
    "//chrome/browser/prefs:util",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/sessions",
    "//chrome/browser/sessions:test_support",
    "//chrome/browser/ui",
    "//chrome/common",
    "//chrome/common:constants",
    "//chrome/test:test_support",
    "//chrome/test:test_support_ui",
    "//components/crash/content/browser/error_reporting:mock_crash_endpoint",
    "//components/crash/core/app",
    "//components/keep_alive_registry",
    "//components/prefs",
    "//components/webui/chrome_urls",
    "//content/public/browser",
    "//content/public/common",
    "//content/test:test_support",
    "//net:test_support",
    "//testing/gmock",
    "//testing/gtest",
    "//ui/base",
    "//ui/events:dom_keycode_converter",
  ]
}