# Copyright 2022 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/buildflag_header.gni")
import("//build/config/chrome_build.gni")

assert(is_chrome_for_testing)

group("chrome_for_testing") {
  deps = [
    ":generate_about_file",
    "//third_party/hyphenation-patterns:bundle_hyphen_data",
  ]
}

action("generate_about_file") {
  script = "//chrome/browser/chrome_for_testing/tools/generate_about_file.py"
  args = [
    "--output-file",
    rebase_path("$root_out_dir/ABOUT"),
  ]
  outputs = [ "$root_out_dir/ABOUT" ]
}

source_set("prefs") {
  sources = [
    "prefs.cc",
    "prefs.h",
  ]

  deps = [
    "//base",
    "//components/prefs",
  ]
}

source_set("browser") {
  sources = [
    "chrome_browser_main_extra_parts_cft.cc",
    "chrome_browser_main_extra_parts_cft.h",
    "config.cc",
    "config.h",
    "switches.h",
  ]

  public_deps = [ ":prefs" ]

  deps = [
    "//base",
    "//chrome/browser:browser_process",
    "//chrome/browser:main_extra_parts",
    "//chrome/browser/headless",
    "//components/component_updater:component_updater_paths",
    "//components/headless/clipboard",
    "//components/prefs",
  ]
}

source_set("unit_tests") {
  testonly = true
  sources = [ "config_unittest.cc" ]

  deps = [
    ":browser",
    "//base",
    "//base/test:test_support",
    "//chrome/browser:browser_process",
    "//components/component_updater:component_updater_paths",
    "//components/prefs:test_support",
    "//testing/gmock",
    "//testing/gtest",
  ]
}

source_set("browser_tests") {
  testonly = true
  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [
    "test/chrome_for_testing_browsertest.cc",
    "test/chrome_for_testing_browsertest.h",
    "test/chrome_for_testing_infobar_browsertest.cc",
  ]

  deps = [
    ":browser",
    "//base",
    "//chrome/browser",
    "//chrome/browser/infobars",
    "//chrome/browser/user_education",
    "//chrome/test:test_support",
    "//components/headless/clipboard",
    "//testing/gmock",
    "//testing/gtest",
    "//ui/base/clipboard:clipboard_test_support",
  ]
}