# Copyright 2024 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_chromeos)

static_library("platform_keys") {
  sources = [
    "platform_keys_service.cc",
    "platform_keys_service.h",
    "platform_keys_service_factory.cc",
    "platform_keys_service_factory.h",
    "platform_keys_service_nss.cc",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]

  deps = [
    "//ash/constants",
    "//base",
    "//chrome/browser/ash/kcer",
    "//chrome/browser/ash/profiles",
    "//chrome/browser/net",
    "//chrome/browser/profiles:profile",
    "//chromeos/ash/components/chaps_util",
    "//chromeos/ash/components/kcer",
    "//chromeos/ash/components/network",
    "//chromeos/ash/components/platform_keys",
    "//chromeos/components/certificate_provider",
    "//components/keyed_service/core",
    "//components/policy/core/common",
    "//components/user_manager",
    "//content/public/browser",
    "//crypto",
    "//net",
  ]
}

static_library("keystore_service") {
  sources = [
    "keystore_service.cc",
    "keystore_service.h",
    "keystore_service_factory.cc",
    "keystore_service_factory.h",
  ]

  public_deps = [ "//chrome/browser:browser_public_dependencies" ]

  deps = [
    ":platform_keys",
    "//ash",
    "//ash/constants",
    "//base",
    "//chrome/browser/ash/attestation",
    "//chrome/browser/ash/platform_keys/key_permissions",
    "//chrome/browser/ash/profiles",
    "//chrome/browser/chromeos/platform_keys",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/profiles:profile_manager",
    "//chromeos/ash/components/dbus/attestation:attestation_proto",
    "//chromeos/ash/components/platform_keys",
    "//components/keyed_service/core",
    "//content/public/browser",
    "//crypto",
    "//net",
  ]

  allow_circular_includes_from = [ "//chrome/browser/chromeos/platform_keys" ]
}

static_library("test_support") {
  testonly = true

  sources = [
    "mock_platform_keys_service.cc",
    "mock_platform_keys_service.h",
    "platform_keys_service_test_util.cc",
    "platform_keys_service_test_util.h",
  ]

  deps = [
    ":platform_keys",
    "//base",
    "//base/test:test_support",
    "//chromeos/ash/components/platform_keys",
    "//crypto",
    "//testing/gmock",
  ]
}

source_set("unit_tests") {
  testonly = true

  sources = [ "keystore_service_unittest.cc" ]

  deps = [
    ":keystore_service",
    ":platform_keys",
    ":test_support",
    "//ash",
    "//base",
    "//base/test:test_support",
    "//chrome/browser/ash/attestation:test_support",
    "//chrome/browser/ash/platform_keys/key_permissions:test_support",
    "//chrome/test:test_support",
    "//chromeos/ash/components/platform_keys",
    "//content/public/browser",
    "//content/test:test_support",
    "//net:test_support",
    "//testing/gmock",
    "//testing/gtest",

    # Gather unit tests from subdirectories.
    "//chrome/browser/ash/platform_keys/key_permissions:unit_tests",
  ]
}

source_set("browser_tests") {
  testonly = true

  defines = [ "HAS_OUT_OF_PROC_TEST_RUNNER" ]

  sources = [ "platform_keys_service_browsertest.cc" ]

  deps = [
    ":platform_keys",
    ":test_support",
    "//base",
    "//chrome/browser/policy:test_support",
    "//chrome/browser/profiles:profile",
    "//chrome/browser/ui",
    "//chrome/test:test_support",
    "//chromeos/ash/components/chaps_util:test_support",
    "//chromeos/ash/components/kcer:chaps_proto",
    "//chromeos/ash/components/platform_keys",
    "//components/policy/core/common",
    "//crypto",
    "//net",
    "//net:test_support",
    "//testing/gmock",
    "//testing/gtest",

    # Gather browser tests from subdirectories.
    "//chrome/browser/ash/platform_keys/key_permissions:browser_tests",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}