# Copyright 2013 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

import("//build/config/compiler/compiler.gni")
import("//build/config/logging.gni")

config("symbolize_config") {
  defines = [
    # Only built for Linux and ChromeOS so no special export magic needed.
    "GLOG_EXPORT=",
  ]
}

static_library("symbolize") {
  visibility = [ "//base/*" ]
  sources = [
    "config.h",
    "demangle.cc",
    "demangle.h",
    "glog/logging.h",
    "glog/raw_logging.h",
    "symbolize.cc",
    "symbolize.h",
    "utilities.h",
  ]

  defines = []

  if (print_unsymbolized_stack_traces) {
    defines += [ "PRINT_UNSYMBOLIZED_STACK_TRACES" ]
  }

  # Symbolization is quite slow when not built in optimized, so always optimize
  # it.
  configs -= [
    "//build/config/compiler:chromium_code",
    "//build/config/compiler:default_optimization",
  ]
  configs += [
    "//build/config/compiler:no_chromium_code",
    "//build/config/compiler:optimize_max",
  ]

  public_configs = [ ":symbolize_config" ]
}