# Copyright 2021 The Chromium Authors
# Use of this source code is governed by a BSD-style license that can be
# found in the LICENSE file.

assert(is_chromeos, "Quick Pair protocols (e.g. Fast Pair) are ash-chrome only")

source_set("ui") {
  output_name = "quick_pair_ui"

  sources = [
    "actions.cc",
    "actions.h",
    "fast_pair/fast_pair_notification_controller.cc",
    "fast_pair/fast_pair_notification_controller.h",
    "fast_pair/fast_pair_presenter.h",
    "fast_pair/fast_pair_presenter_impl.cc",
    "fast_pair/fast_pair_presenter_impl.h",
    "ui_broker.h",
    "ui_broker_impl.cc",
    "ui_broker_impl.h",
  ]

  deps = [
    "//ash/constants",
    "//ash/public/cpp",
    "//ash/quick_pair/common",
    "//ash/quick_pair/proto:fastpair_proto",
    "//ash/quick_pair/repository",
    "//ash/resources/vector_icons",
    "//ash/strings",
    "//base",
    "//components/cross_device/logging",
    "//components/signin/public/base",
    "//components/signin/public/identity_manager",
    "//third_party/protobuf:protobuf_lite",
    "//ui/base",
    "//ui/gfx",
    "//ui/message_center",
    "//url",
  ]

  # TODO(crbug.com/40031409): Fix code that adds exit-time destructors and
  # enable the diagnostic by removing this line.
  configs += [ "//build/config/compiler:no_exit_time_destructors" ]
}

static_library("test_support") {
  testonly = true

  sources = [
    "actions.cc",
    "actions.h",
    "mock_ui_broker.cc",
    "mock_ui_broker.h",
    "ui_broker.h",
  ]

  deps = [
    "//ash/quick_pair/common",
    "//base",
    "//base/test:test_support",
    "//testing/gtest",
  ]
}

source_set("unit_tests") {
  testonly = true

  sources = [
    "fast_pair/fast_pair_notification_controller_unittest.cc",
    "fast_pair/fast_pair_presenter_impl_unittest.cc",
    "ui_broker_impl_unittest.cc",
  ]

  deps = [
    ":test_support",
    ":ui",
    "//ash:test_support",
    "//ash/constants",
    "//ash/public/cpp:test_support",
    "//ash/quick_pair/common",
    "//ash/quick_pair/common:test_support",
    "//ash/quick_pair/proto:fastpair_proto",
    "//ash/quick_pair/repository",
    "//ash/quick_pair/repository:test_support",
    "//base",
    "//base/test:test_support",
    "//chromeos/ash/services/quick_pair",
    "//chromeos/ash/services/quick_pair:test_support",
    "//chromeos/ash/services/quick_pair/public/cpp",
    "//components/signin/public/identity_manager",
    "//components/signin/public/identity_manager:test_support",
    "//testing/gtest",
    "//ui/base",
    "//ui/message_center",
    "//ui/message_center:test_support",
  ]
}